Extract sentences containing a keyword and output results to Excel

[reddwarf]

Hello.
I found the attached code on Microsoft Community by Graham Mayor which searches a Word document (I'm using Office 365) for a keyword and outputs the sentence to Excel. It works really well. I was wondering if someone could extend the code so that it also outputs the line number and page number too - this would be really helpful

Thank you

Sub ExtractLine()
Dim oPara As Paragraph
Dim xlApp As Object
Dim xlBook As Object
Dim NextRow As Long
Dim oRng As Range
Dim strWord As String
Const strWorkbookname As String = "D:\My Documents\WorkbookName.xlsx"
    strWord = InputBox("Enter word to find")
    Set oRng = ActiveDocument.Range
    With oRng.Find
        Do While .Execute("^l")
            oRng = vbCr
            oRng.Collapse wdCollapseEnd
        Loop
    End With
    On Error Resume Next
    Set xlApp = GetObject(, "Excel.Application")
    If Err Then
        Set xlApp = CreateObject("Excel.Application")
    End If
    On Error GoTo 0
    Set xlBook = xlApp.Workbooks.Open(Filename:=strWorkbookname)
    xlApp.Visible = True
    Set oRng = ActiveDocument.Range
    With oRng.Find
        Do While .Execute(strWord)
            NextRow = xlBook.Sheets(1).Range("A" & xlBook.Sheets(1).Rows.Count).End(-4162).Row + 1
            oRng.Start = oRng.Paragraphs(1).Range.Start
            oRng.End = oRng.Paragraphs(1).Range.End - 1
            xlBook.Sheets(1).Range("A" & NextRow) = oRng.Text
            oRng.Collapse wdCollapseEnd
        Loop
    End With
End Sub

[macropod]

After:

            xlBook.Sheets(1).Range("A" & NextRow) = oRng.Text

Insert:

            xlBook.Sheets(1).Range("B" & NextRow) = oRng.Information(wdActiveEndPageNumber)
            xlBook.Sheets(1).Range("C" & NextRow) = oRng.Information(wdFirstCharacterLineNumber)

[302]

Hello, everyone. I accidentally browsed this webpage and found that this code is really practical.
On this basis, I want to raise a demand. I wonder if anyone can answer it.
According to the code of post # 1, you can only paste the code to the word document you want to find.
Can you fix a blank word document to store the code, pop up the document selection box to select the file each time you execute the macro, and then other codes are the same?

[macropod]

According to the code of post # 1, you can only paste the code to the word document you want to find.

The code can be stored in any document or template. The only proviso when running the code is that the document you want to process must be the active one (i.e. on-screen when you run the code).

[302]

can I use the pop up window select file ?

[reddwarf]

Thank you - this works.
I had worked out from internet research that wdActiveEndPageNumber is used to capture page numbers but wasn't sure how to implement. Great job.

[macropod]

Not without rewriting parts of the code. For example, you might replace:

    strWord = InputBox("Enter word to find")
    Set oRng = ActiveDocument.Range

with:

Set oRng = Nothing
With Application.Dialogs(wdDialogFileOpen)
  If .Show = -1 Then
    .AddToMru = False
    .ReadOnly = True
    .Visible = False
    .Update
    Set oRng = ActiveDocument.Range
  End If
End With
If oRng Is Nothing Then Exit Sub
strWord = InputBox("Enter word to find")

[302]

wow, you are great , thanks a lot.