Extracting Data from Word Table to Excel 2013 into specific columns

Assuming there's only one table per document to process, try:

Sub GetDocData()
     'Note: this code requires a reference to the Word object model
    Application.ScreenUpdating = False
    Dim wdApp As New Word.Application, wdDoc As Word.Document
    Dim strFolder As String, strFile As String, strCols As String, strTmp As String
    Dim xlWkSht As Worksheet, lRow As Long, lCol As Long, r As Long, c As Long
    strFolder = GetFolder & "\"
    If strFolder = "\" Then Exit Sub
    Set xlWkSht = ActiveSheet: strCols = "|"
    With xlWkSht
        With .UsedRange.Cells.SpecialCells(xlCellTypeLastCell)
            lRow = .Row
            lCol = .Column
        End With
        For c = 1 To lCol
            strCols = strCols & .Cells(1, c).Value & "|"
        Next
    End With
    strFile = Dir(strFolder & "*.doc", vbNormal)
    While strFile <> ""
        Set wdDoc = wdApp.Documents.Open(Filename:=strFolder & strFile, AddToRecentFiles:=False, ReadOnly:=True, Visible:=False)
        With wdDoc
            If .Tables.Count > 0 Then
                lRow = lRow + 1
                With .Tables(1)
                    For r = 1 To .Rows.Count
                        strTmp = Split(.Cell(r, 1).Range.Text, vbCr)(0)
                        If (InStr(strCols, "|" & strTmp & "|") > 0) Or (InStr(Replace(strCols, " ", "_"), "|" & strTmp & "|") > 0) Then
                            For c = 1 To lCol
                                If (strTmp = Split(strCols, "|")(c)) Or (strTmp = Replace(strCols, " ", "_")) Then
                                    xlWkSht.Cells(lRow, c).Value = Split(.Cell(r, 2).Range.Text, vbCr)(0)
                                    Exit For
                                End If
                            Next
                        End If
                    Next
                End With
            End If
            .Close SaveChanges:=False
        End With
        strFile = Dir()
    Wend
    wdApp.Quit
    Set wdDoc = Nothing: Set wdApp = Nothing: Set xlWkSht = Nothing
    Application.ScreenUpdating = True
End Sub
 
Function GetFolder() As String
    Dim oFolder As Object
    GetFolder = ""
    Set oFolder = CreateObject("Shell.Application").BrowseForFolder(0, "Choose a folder", 0)
    If (Not oFolder Is Nothing) Then GetFolder = oFolder.Items.Item.Path
    Set oFolder = Nothing
End Function

With this code, it doesn't matter which rows are present in, or absent from, a given table; provided there is a match between the title on a row and a given column name, any data that are present will be output to the corresponding Excel column.

Assuming the new column is to go between the existing two, you could change:
xlWkSht.Cells(lRow, c).Value = Split(.Cell(r, 2).Range.Text, vbCr)(0)
to:
xlWkSht.Cells(lRow, c).Value = Split(.Cell(r, 3).Range.Text, vbCr)(0)

If the new column is to go before the existing two, you would also need to change:
strTmp = Split(.Cell(r, 1).Range.Text, vbCr)(0)
to:
strTmp = Split(.Cell(r, 2).Range.Text, vbCr)(0)

If the new column is to go after the existing two, you don't need to make any changes.