VBA Code to Convert/Print Selected Pages of Word Document to PDF File

[DD1]

The code below creates a PDF file from Excel of a Word document. The name of the file is exactly the same except it has a 'pdf' extension rather than 'docx'. The ", 17" at the end of the last line of code gives it the 'pdf' extension.
The file is 3 pages.
The main thing I would like to do is create 2 PDF files - one is of just the first page and the other is of pages 2-3.
I don't know what the code is to specify page ranges.
The other thing I would like to do is suppress the message that comes up when the second from last line of code is executed - i.e. the one that opens the Word file. It currently says the file is locked for editing and has 3 options for opening the file. I just want to open the file as read-only (which is option 1).
Also can you tell me how to add this code properly to the thread? At the moment I have just pasted it in from the VBA editor.

Many thanks
David

Sub Create_PDF_File_of_Word_Document()

Dim wordFile As Object
Set wordFile = CreateObject("Word.Application")

Directory_Path = "C:\Data"
Filename = "Jul-15 Variance Analysis.docx"

Set wordDoc = wordFile.Documents.Open(Directory_Path & "\" & Filename)

wordDoc.ExportAsFixedFormat Left(wordDoc.FullName, InStrRev(wordDoc.FullName, ".") - 1), 17

End Sub

[macropod]

You really should look up Word's ExportAsFixedFormat and Open methods for this. You should also declare all variables and, presumably, close the document and quit Word when you're done.

Try:

Sub Create_PDF_File_of_Word_Document()
Dim wdApp As Object, wdDoc As Object, StrPath As String, StrFlNm As String
StrPath = "C:\Data\"
StrFlNm = "Jul-15 Variance Analysis.docx"
Set wdApp = CreateObject("Word.Application")
With wdApp
  '.Open FileName:=StrPath & StrFlNm , ReadOnly:=True, AddToRecentFiles:=False
  Set wdDoc = .Documents.Open(StrPath & StrFlNm, True, False)
  With wdDoc
    'ExportAsFixedFormat Outputfilename:=.FullName, Exportformat:=wdExportFormatPDF, _
    'OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, Range:=wdExportFromTo, From:=1, To:=1
    .ExportAsFixedFormat Split(.FullName, ".doc")(0) & "A.pdf", 17, 0, False, 3, 1, 1
    .ExportAsFixedFormat Split(.FullName, ".doc")(0) & "B.pdf", 17, 0, False, 3, 2, 3
    .Close
  End With
  .Quit
End With
Set wdDoc = Nothing: Set wdApp = Nothing
End Sub

[DD1]

Thank you Paul. I will give this a go when I get to work tomorrow and let you know how I get on.
Cheers
David

[DD1]

Thank you Paul. That worked perfectly.

If the Word document had more than 3 pages, is it possible when creating the second PDF file to print from page 2 to the end of the document?
I had a look at Word's ExportAsFixedFormat method but couldn't see that it was possible. I tried a couple of things, but wasn't able to get it to work.

Also, is it possible to append one pdf file to another with VBA? I would like to do this from Excel.
I can do it manually, but can't work out what the code is.

Thanks for your help Paul.
Regards,
David

[macropod]

If the Word document had more than 3 pages, is it possible when creating the second PDF file to print from page 2 to the end of the document?
I had a look at Word's ExportAsFixedFormat method but couldn't see that it was possible. I tried a couple of things, but wasn't able to get it to work.

That's easy: simply replace the '3' with:
.ComputeStatistics(2) '2 = wdStatisticPages

Also, is it possible to append one pdf file to another with VBA? I would like to do this from Excel.
I can do it manually, but can't work out what the code is.

Not from MS Office. You could, however, automate Adobe Acrobat Pro and have it do that. Adobe Acrobat Pro 8 is available as a free download. I don't know the relevant Adobe code to combine files, but people on an Adobe forum should be able to tell you that (or a web search might turn up the code).

[DD1]

Thanks a lot Paul. That works brilliantly.
I really appreciate your help.
Regards,
David