'Continue For' gives error (does not work)

I am working on MS Word 2010. When I use 'Continue For', it gives error ("Expected: Expression").

For Each Tbl In ActiveDocument.Tables           'Look thru ALL the document tables
  '... blah blah blah ...
   If .Find.Found = False Then Continue For     'If not found, then go to next table
   '... blah blah blah ...
  End With                                      'Quite associating with Tbl.Range object
Next Tbl                                        'If here, don't have descrip yet; goto next Tbl

I am on Word 2010, VBA 7.0
I get a red error on the 'Continue For'; what possibility could be wrong with this?
I've never used a 'Continue For' before.
(I've got the .Find.Found properly associated; so don't worry about that; I only show the above streamlined so to zero in on the 'Continue For' part)

As mehmetcik indicates, there is no 'Continue For' in Word VBA.

It's not clear what you're trying to achieve, but perhaps the following macros will give you some pointers. The first one bolds the found text wherever it is found in a table. The second one bolds it only if it's in column 2 in a table.

Sub Demo1()
Application.ScreenUpdating = False
Dim Tbl As Table
For Each Tbl In ActiveDocument.Tables
  With Tbl.Range.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "Text to Find"
    .Replacement.Text = "^&"
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
    .Replacement.Font.Bold = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = False
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    .Execute Replace:=wdReplaceAll
  End With
Next Tbl
Set Tbl = Nothing
Application.ScreenUpdating = True
End Sub

Sub Demo2()
Application.ScreenUpdating = False
Dim Tbl As Table
For Each Tbl In ActiveDocument.Tables
  With Tbl.Range
    With .Find
      .ClearFormatting
      .Replacement.ClearFormatting
      .Text = "Text to Find"
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindStop
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
    Do While .Find.Found
      If .InRange(Tbl.Range) Then
        If .Cells(1).ColumnIndex = 2 Then .Duplicate.Font.Bold = True
      Else: Exit Do
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
Next Tbl
Application.ScreenUpdating = True
End Sub