How to prompt user to select file to attach to an E-Mail (Excel to Outlook)

Hi,

I have a userform in Excel which contains a button with code that automatically creates and displays, ready for sending an E-Mail.

However, I want to take the code further and once the E-Mail has been created/displayed, it then prompts the user to select a file from a certain path to then attach to the E-Mail ready for sending.

I can't seem to work out how to do this last bit, asking the user to select a file to attach.

Can anyone help with this llast bit of code?

Cheers,

TLP.

Hi..

Try this.. it will allow you to see any filetype in the browse Dialogue... if you want.. you can restrict what shows by changing the 4th line of code..

Private Sub CommandButton1_Click()
    Dim OutApp, OutMail As Object
    Dim wbFullName As Variant

    wbFullName = Application.GetOpenFilename("All Files (*.*), *.*")
    
    If wbFullName = False Then
        Exit Sub
    End If

    On Error Resume Next
    Application.ScreenUpdating = False
    Set OutApp = CreateObject("Outlook.Application")

    On Error GoTo cleanup
            Set OutMail = OutApp.CreateItem(0)
            On Error Resume Next
            With OutMail
                .To = Cells(2, 2).Value
                .Subject = "Test"
                .Attachments.Add (wbFullName)
                .Display  'Or use .Send
            End With
            On Error GoTo 0
            Set OutMail = Nothing
        
cleanup:
    Set OutApp = Nothing
    Application.ScreenUpdating = True
End Sub

This worked a treat.

Thank you!