How to set reminders from Excel data

Hi,

I need help to set a reminder in outlook to remind me of the billing schedule. However, I have long list of it and it is in excel. I would like to know if there's a way to set a remnder in outlook while getting its data in Excel. Let's say for Example: In column A- the date that i need to issue the Invoice, in column B- the name of the customer that needs to be invoice. In the reminder, I want to appear in the reminder : Please invoice customer ###(referring to column B).

Hope you can help me.

Thanks

Assuming that the data starts at Row 2 in Column A, try...

Option Explicit

Sub CreateTasks()

    Dim olApp As Object
    Dim olTask As Object
    Dim LastRow As Long
    Dim i As Long
    
    Set olApp = CreateObject("Outlook.Application")
    
    LastRow = Cells(Rows.Count, "A").End(xlUp).Row
    
    For i = 2 To LastRow
        If Cells(i, "A").Value <> "" Then
            Set olTask = olApp.CreateItem(3) 'olTaskItem
            With olTask
                .Subject = "Invoice - " & Cells(i, "B").Value
                .Body = "Please invoice customer " & Cells(i, "B").Value & "."
                .Status = 1 'olTaskInProgress
                .Importance = 2 'olImportanceHigh
                .DueDate = Cells(i, "A").Value
                .ReminderSet = True
                .ReminderTime = Cells(i, "A").Value + TimeValue("09:00:00")
                .Save
            End With
        End If
    Next i
        
End Sub

Note that the reminder is set for 9:00 AM on the due date. Change this and other properties, accordingly.

Thank you very much. The code is working. You are such a great help..thank you ..

You're very welcome! Thanks for the feedback!

Hi I am new to this, but seems like very interesting, please let me how could I work an example or please send me a sample excel file. Thanks, Bob

great job!!!!

please i need similar macro to set reminders from excel data. i have registered with the site but still cant access it