Need Notification of Daily Email Not Received

You will have to try some VBA

' 1 - Set up a recurring task with subject OnQReports
'      with a reminder set later than the mail is expected
'
' 2 - Put this code in ThisOutlookSession

Private Sub Application_Reminder(ByVal Item As Object)

If Item.Class = olTask Then
    If InStr(Item.Subject, "OnQReports") > 0 Then
        ReminderUnreceivedMail_OnQReports
    End If
End If

End Sub

' 3 - Put this code in a regular module. 
'      To make it simpler,
'      this code may go in the ThisOutlookSession module.
'
' In normal use the reminder should trigger this code
' You may run this manually to test if it works

Private Sub ReminderUnreceivedMail_OnQReports()

Dim itms As Items

' The folder name is OnQReports. It is one level below the Inbox
' If the folder is at another level add more of
'   .Folders("SubfolderNameX")
' Set itms = GetNamespace("MAPI").GetDefaultFolder(olFolderInbox).Folders("SubfolderName1").Folders("OnQReports").Items

Set itms = GetNamespace("MAPI").GetDefaultFolder(olFolderInbox).Folders("OnQReports").Items

Set itms = itms.Restrict("[SentOn] > '" & Format(Date, "yyyy-mm-dd") & "'")

If itms.count = 0 Then
    MsgBox "Warning. No email today " & Format(Date, "yyyy-mm-dd")
Else
    MsgBox "Email received today " & Format(Date, "yyyy-mm-dd")
End If

Set itms = Nothing

End Sub

If you are not familiar with VBA this may prove helpful. http://www.slipstick.com/developer/h...ks-vba-editor/