Isolate the last 3 used area of the column

Hello, few years back. I do have problem finding last empty cell on a column and inserting, copy paste the last non empty column. Now, I do have same problem again but this time I have to copy the last 3 non empty columns and paste it on 3 inserted column. Here is the piece of successful code with my previous problem. Hope you can modify it. Thanks!

Sub AddCol()
    Dim rng As Range, c As Range
    Set rng = Intersect(ActiveSheet.UsedRange, Rows(2)) ' Isolate row 2
    If rng Is Nothing Then Exit Sub ' Assuming there is more than one row
    Set c = rng.Cells(rng.Cells.Count) ' Isolate the last cell in row 2
    If IsEmpty(c) Then Set c = c.End(xlToLeft) ' Find the last non-empty cell
    If Not IsEmpty(c) Then
        Set rng = Intersect(c.EntireColumn, ActiveSheet.UsedRange) ' Isolate the used area of the column
        rng.Copy ' Copy to clipboard
        rng.Insert Shift:=xlToRight ' Duplicate
        c.Offset(0, -1).Select ' Select the "marker" in the duplicate column
        Application.CutCopyMode = False ' Switch off the CutCopy marquee
    End If
End Sub

How about (try it):

Sub AddCol()
  Dim rng As Range, c As Range, i as long
  for i = 1 to 3
    Set rng = Intersect(ActiveSheet.UsedRange, Rows(2)) ' Isolate row 2
    If rng Is Nothing Then Exit Sub ' Assuming there is more than one row
    Set c = rng.Cells(rng.Cells.Count) ' Isolate the last cell in row 2
    If IsEmpty(c) Then Set c = c.End(xlToLeft) ' Find the last non-empty cell
    If Not IsEmpty(c) Then
        Set rng = Intersect(c.EntireColumn, ActiveSheet.UsedRange) ' Isolate the used area of the column
        rng.Copy ' Copy to clipboard
        rng.Insert Shift:=xlToRight ' Duplicate
        c.Offset(0, -1).Select ' Select the "marker" in the duplicate column
        Application.CutCopyMode = False ' Switch off the CutCopy marquee
    End If
  next i
End Sub

I just added two lines and one declaration of variable. Looking at the structure - it shall work. Or if I understand wrong your concept - try another mod:

Sub AddCol()
  Dim rng As Range, c As Range, i as long
    Set rng = Intersect(ActiveSheet.UsedRange, Rows(2)) ' Isolate row 2
    If rng Is Nothing Then Exit Sub ' Assuming there is more than one row
    Set c = rng.Cells(rng.Cells.Count) ' Isolate the last cell in row 2
  for i = 1 to 3
    If IsEmpty(c) Then Set c = c.End(xlToLeft) ' Find the last non-empty cell
    If Not IsEmpty(c) Then
        Set rng = Intersect(c.EntireColumn, ActiveSheet.UsedRange) ' Isolate the used area of the column
        rng.Copy ' Copy to clipboard
        rng.Insert Shift:=xlToRight ' Duplicate
        c.Offset(0, -1).Select ' Select the "marker" in the duplicate column
        Application.CutCopyMode = False ' Switch off the CutCopy marquee
        Set c = c.offset(0,-2)   'not sute about it: may be -1 - experiment with it
    End If
  next i
End Sub

just a small tip:

Next time post a tiny sample workbook with few input data and desired (manualy "calculated") results.
It makes much easier to test few concepts and choose the best one for those who try to help.

PS. depending on data layout and filled/empty cells it could be wise to add a security measure to the final lines:

        Application.CutCopyMode = False ' Switch off the CutCopy marquee
        if c.column <3 then 
          exit for
        else
          Set c = c.offset(0,-2)   'not sute about it: may be -1 - experiment with it
        end if
    End If

OK. Then yet another approach (and you are right - there are 4 columns indeed, just 3 headers):

Sub AddCol3()
    Dim rng As Range, c As Range
    Set rng = Intersect(ActiveSheet.UsedRange, Rows(2)) ' Isolate row 2
    If rng Is Nothing Then Exit Sub ' Assuming there is more than one row
    Set c = rng.Cells(rng.Cells.Count) ' Isolate the last cell in row 2
    If IsEmpty(c) Then Set c = c.End(xlToLeft) ' Find the last non-empty cell
    If Not IsEmpty(c) Then
        Set rng = Intersect(c.Offset(0, -3).Resize(1, 4).EntireColumn, ActiveSheet.UsedRange) ' Isolate the used area of the 4 columns
        rng.Copy ' Copy to clipboard
        rng.Insert Shift:=xlToRight ' Duplicate
        c.Offset(0, -1).Select ' Select the "marker" in the duplicate column may be here you would like to change -1 to -3?
        Application.CutCopyMode = False ' Switch off the CutCopy marquee
    End If
End Sub

As you see the only change (marked blue) from the original code, is to move c cell left 3 columns from original and made c 4 columns wide before setting rng Range (to be copied and inserted).