Pasting text into a cell that has Upper Case code for the worksheet

It should work if they copy-paste one cell.

You have told code to stop if Target is more than one cell. You may try:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rgCell as Range
    If Not Intersect(Target, Range("A1:A5")) Is Nothing Then
        Application.EnableEvents = False
        For each rgCell in Intersect(Target, Range("A1:A5")).Cells
        rgCell.Value = UCase(rgCell.Value)
        Next rgCell
        Application.EnableEvents = True
    ElseIf Not Intersect(Target, Range("B1:B5")) Is Nothing Then
        Application.EnableEvents = False
        For each rgCell in Intersect(Target, Range("B1:B5")).Cells
        rgCell.Value = Application.Proper(rgCell.Value)
        Next rgCell
        Application.EnableEvents = True
    End If
End Sub

Try this...

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim cell As Range
    On Error GoTo ReEnable
    Application.EnableEvents = False
    If Not Intersect(Target, Range("A1:A5")) Is Nothing Then
        For Each cell In Intersect(Target, Range("A1:A5"))
            cell.Value = UCase(cell.Value)
        Next cell
    End If
    If Not Intersect(Target, Range("B1:B5")) Is Nothing Then
        For Each cell In Intersect(Target, Range("B1:B5"))
            cell.Value = Application.Proper(cell.Value)
        Next cell
    End If
ReEnable:
    Application.EnableEvents = True
    If Err.Number <> 0 Then MsgBox "Worksheet_Change event procedure: " & vbLf & _
                                   Err.Description, vbCritical, "Error " & Err.Number
End Sub