Run multiple if statements

[rlh]

What I am trying to do is run the code below for the same worksheet.

The problem is Excel will only allow me to run one or the other.

I want them to work at the same time.

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("A1:A5")) Is Nothing Or Target.Cells.Count > 1 Then Exit Sub
Application.EnableEvents = False
Target.Value = UCase(Target.Value)
Application.EnableEvents = True

If Intersect(Target, Range("B1:B5")) Is Nothing Or Target.Cells.Count > 1 Then Exit Sub
Application.EnableEvents = False
Target.Value = Application.Proper(Target.Value)
Application.EnableEvents = True
End Sub

Any help is greatly appreciated

[protonLeah]

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, Range("A1:A5")) Is Nothing Then
        Application.EnableEvents = False
        Target.Value = UCase(Target.Value)
        Application.EnableEvents = True
    ElseIf Not Intersect(Target, Range("B1:B5")) Is Nothing Then
        Application.EnableEvents = False
        Target.Value = Application.Proper(Target.Value)
        Application.EnableEvents = True
    End If
End Sub

[ajryan88]

Hi,

Firstly, could you please indent your code in the future, it makes it a lot easier to read. Secondly, just remove the Exit Sub statements, and reverse the polarity of the If...Then statements, like this:

Private Sub Worksheet_Change(ByVal Target As Range)
	If Not Intersect(Target, Range("A1:A5")) Is Nothing And Target.Cells.Count <= 1 Then
		Application.EnableEvents = False
		Target.Value = UCase(Target.Value)
		Application.EnableEvents = True
	End If
	
	If Not Intersect(Target, Range("B1:B5")) Is Nothing And Target.Cells.Count <= 1 Then
		Application.EnableEvents = False
		Target.Value = Application.Proper(Target.Value)
		Application.EnableEvents = True
	End If
End Sub

Please note, I haven't tested this, I have done it off the top of my head. So please let me know if it still doesn't do what you're looking for and I'll take another look at it.

I hope this helps

[rlh]

Thank you very much. This worked perfectly.

[rlh]

Thank you protonleah. That worked perfectly.

[ajryan88]

Please don't forget to mark this thread as solved