How to delete entire row if first cell of it is empty for specific range and worksheets

Hi I have a workbook as attached.
The work sheets are named as first page,last page, static sheet, dynamic sheet and transfer sheet. the dynamic sheets add up every day for this workbook.
My macro should Delete the entire row if its cell in column "A" is empty.
Restrictions
1. Macro should not work for first and last work sheets
2. The range for static sheets(should be from "A5" row to the last used row) is different from dynamic sheets(should be from "A7" row to the last used row)
3. In transfer sheet, the macro should run for rows below the black stripped row and also for the columns after the black stripped column if any cell from D8 is empty delete the entire column.
I have written the macro as below but when I run the macro, it is only working for static pages and when i select any dynamic page and re-run the macro, it is performing for all the dynamic pages. Also I am not able to select the range for transfer sheet and perform the macro.

Please help!!!

Sub DL()

 Dim ws As Worksheet
For Each ws In ActiveWorkbook.Worksheets
         With ws
         ' Discarding first, last and transfer sheet
         If .Name <> "First Sheet" And .Name <> "Last Sheet" And .Name <> "Transfer sheet" Then
         ' To delete all blank rows in static sheets
         If .Name = "Static Sheet1" Or .Name = "Static Sheet2" Or _
        .Name = "Static Sheet3" Or .Name = "Static Sheet4" Then
         .Range("A5:A" & Range("A" & Rows.Count).End(xlUp).Row).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
         Else
         ' To delete all blank rows in dynamic sheets
         .Range("A7:A" & Range("A" & Rows.Count).End(xlUp).Row).SpecialCells(xlCellTypeBlanks).EntireRow.Delete
         End If
         'To delete all blank rows in transfer sheet from cells below black row and beside black column
         'Else
         'If .Name = "Transfer sheet" Then
         End If
         On Error Resume Next
         End With
       
    Next ws
End Sub

Just to clarify ... In the "Transfer sheet", if any cell in column A starting at row 25 is empty, you want to delete the entire row. Also if any cell in the range D8:AD8 is empty, you want to delete the entire column. Is this correct?

Hi roshanvmech. I think that Leith has you covered.

Hello roshanvmech,

The macros below work for the static and dynamic sheets and leaves the First and Last sheets alone. It wasn't clear to me from the post or the workbook what to do with the Transfer sheet. If you provide a good example of which cells are to checked, I can then write the code for the macro. Here are the macros' code. These have been added to the attached workbook.

Macros are in the ThisWorkbook Module of the VBA Project

Sub Macro1()

    Dim Wks     As Worksheet
    Dim WksName As String
    
        For Each Wks In Worksheets
        
            WksName = LCase(Wks.Name)
            
            Select Case WksName
                Case Is = "first sheet", "last sheet"
                    ' Ignore these sheets.
                Case Is = "transfer"
                    ' ???
                Case Else
                    If WksName Like "static*" Then
                        Call DeleteRows(Wks.Range("A5"))
                    End If
                    
                    If WksName Like "dynamic*" Then
                        Call DeleteRows(Wks.Range("A7"))
                   End If
            End Select
        Next Wks
        
End Sub

Sub DeleteRows(ByRef Rng As Range)

    Dim RngEnd  As Range
    Dim row     As Long
    Dim Wks     As Worksheet
    
        Set Wks = Rng.Parent
        
        Set RngEnd = Wks.Cells(Rows.Count, Rng.Column).End(xlUp)
        If RngEnd.row < Rng.row Then Exit Sub
        
        Set Rng = Wks.Range(Rng, RngEnd)
        
        Application.ScreenUpdating = False
            For row = Rng.Rows.Count To 1 Step -1
                If IsEmpty(Rng.Item(row, 1)) Then
                    Rng.Cells(row, 1).EntireRow.Delete
                End If
            Next row
        Application.ScreenUpdating = True
        
End Sub