VBA combo box add unique values only

[randell.graybill]

I am trying to populate a combo box with unique values, what am I doing wrong? Getting runtime error '381': Could not set the List property. Invalid property array index
errors out on this line: If LCase(frmMain.cmbCategory.List(r2)) = LCase(val) Then Exit Sub on the second pass, works during the first pass through though.

LR = Sheets(3).Range("C" & Rows.Count).End(xlUp).Row

Sheets(3).Select
For r = r To LR Step 1
    val = Sheets(3).Range("C" & r2 + 2).value
    If LCase(frmMain.cmbCategory.List(r2)) = LCase(val) Then Exit Sub
    v = Sheets(3).Range("C" & r).value
    frmMain.cmbCategory.AddItem v, r2
    r2 = r2 + 1
Next r

[Tinbendr]

This is how I do that.

Private Sub UserForm_Initialize()

Dim Unique As New Collection
Dim StartRow As Long
Dim LastRow As Long

StartRow = 3

With Sheets(3)
    LastRow = .Range("C" & .Rows.Count).End(xlUp).Row
    
    For A = StartRow To LastRow
        On Error Resume Next
        Unique.Add CStr(.Range("C" & A)), CStr(.Range("C" & A))
        On Error GoTo 0
    Next
End With

    For A = 1 To Unique.Count
        frmMain.cmbCategory.AddItem Unique(A)
    Next
    
End Sub

A collection can't have the same values (Well keys actually, but in this case they are the same), so we take advantage of that by trying to add the whole range. But the On Error skips the duplicate entries so that you end up with a unique list.

NitPiks
1. avoid using Val as a variable name since it is also a function A = Val("1") would return the NUMBER 1.
2. Since you are referring to a specific range, there's no need to select the sheet first. (Unless you have a specific need to.)
3. If you count positively through a loop, Step 1 is the default, so there's no need to spell it out.