Userform with multiple checkboxes used for autofilter

Try something like this...

Private Sub CommandButton4_Click()
    
    Dim i As Long, j As Long
    Dim D() As String, K() As String
    ReDim D(1 To 20): ReDim K(1 To 5)
    
    'Build array of checked items (Projects)
    For i = 6 To 25
        If Me.Controls("CheckBox" & i).Value = True Then
            j = j + 1
            With Me.Controls("Label" & i + 5)
                D(j) = Left(.Caption, InStr(.Caption, " (") - 1) 'remove (#) from caption
            End With
        End If
    Next i
    If j > 0 Then
        ReDim Preserve D(1 To j)
    Else
        MsgBox "Nothing selected", , "Projects"
        Exit Sub
    End If
    
    'Build array of checked items (Prioriteit)
    j = 0
    For i = 1 To 5
        If Me.Controls("CheckBox" & i).Value = True Then
            j = j + 1
            K(j) = Me.Controls("Label" & Array(3, 4, 5, 6, 31)(i - 1)).Caption
        End If
    Next i
    If j > 0 Then
        ReDim Preserve K(1 To j)
    Else
        MsgBox "Nothing selected", , "Prioriteit"
        Exit Sub
    End If
    
    'Autofilter
    With Sheets("UIT TE VOEREN").AutoFilter.Range
        .AutoFilter Field:=2, Criteria1:=D, Operator:=xlFilterValues
        .AutoFilter Field:=9, Criteria1:=K, Operator:=xlFilterValues
    End With
    
End Sub

Originally Posted by JorisDDS

Thanks for the help so far ; I had to adjust a few things because you put the values in the labels in the array where the labels of the projects contain other information too. Giving the following code :

while testing I noticed that the arrays don't seem to build up as they should. The filter only works for the first added value, not the others in the array So if I check the A and B priority it only filters on A priority and hides the B.

I thought I had stripped out the other info from the Labels.
D(j) = Left(.Caption, InStr(.Caption, " (") - 1) 'remove (#) from caption

Tip: instead of the x variable, you could use j + 7. This is not your problem though.
D(j) = (Sheets("Tabellen").Cells(j + 7, "S").Value)

Your example workbook had autofillter only on columns C5:V5. (not column B).
Your code in AlgemeenOverzicht_Click includes column B in the Autofilter range.

Private Sub AlgemeenOverzicht_Click()
ActiveSheet.Range("$B$5:$V$5000").AutoFilter Field:=20, Criteria1:="=true"

If column B is included, then change this...

    'Autofilter
    With Sheets("UIT TE VOEREN").AutoFilter.Range
        .AutoFilter Field:=20, Criteria1:="true"
        .AutoFilter Field:=3, Criteria1:=D, Operator:=xlFilterValues
        .AutoFilter Field:=10, Criteria1:=k, Operator:=xlFilterValues
    End With

The field number is dependent on the columns you include in the filter range. (Hidden columns are not counted)


Also: Be aware that filter criteria for the three columns (column D, column K, and you added column 20 = "true") are addative. All three columns have to match one critera in their respective Array. If there is a match in column D, there would also have to be a match in column K for that same row for it to be visible (and column 20 has to also equal True). Your example file doesn't have any values in column 20. As best I can tell that is column AA based on the columns you have hidden.

You can use this autofilter for column 20 as its' criteria is not an array.
.AutoFilter Field:=20, Criteria1:="true"

You're welcome. I din't know about the hidden columns not being counted as well until I tested it.