Range Select from another worksheet

Private Sub ComboBox1_Change()
 
Dim uCode As Integer
uCode = 1234
 
Dim Vals As String
  Vals = AccessCredentials.ComboBox1.Value
 
 
With Sheets("Sheet1").Range("A:A")
    Set c = .Find(Vals, LookIn:=xlValues)
      c.Select
    If Not c Is Nothing Then
        firstAddress = c.Address
        Do
            'MsgBox (c)
            Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> firstAddress
    End If
End With
 
 
 
 
If ComboBox1 = "Applications" Then
Me.TextBox1.Value = ""
Me.TextBox2.Value = ""
Me.TextBox3.Value = ""
Me.TextBox4.Value = ""
Else
Me.TextBox1.Value = ActiveCell.Offset(, 4).Value & vbCrLf & ActiveCell.Offset(, 5).Value & vbCrLf & ActiveCell.Offset(, 6).Value & vbCrLf & ActiveCell.Offset(, 7).Value
Me.TextBox2.Value = ActiveCell.Offset(, 1).Value
Me.TextBox4.Value = ActiveCell.Offset(, 3).Value
If Me.TextBox5.Value = uCode Then
Me.TextBox3.Value = ActiveCell.Offset(, 2).Value
End If
End If
 
End Sub

This only works when Sheet1 is selected. If Sheet2 is selected, it returns an error of

1004
Select method of Range class failed.

Sheet1 and Sheet2 are the only sheets in my entire book... When I debug, it goes to the c.Select line...

I've tried referencing the Sheet1 exactly with Sheets("Sheet1").Range("A:A") and every other possible combination I can think of...
I do NOT want Sheet1 to need to be selected or even visible necessarily.
Also the Vals variable is set earlier in the code and returns the correct information...

Why do you want to select c?

Can't you use c instead if ActiveCell in the later code?

If you mean why doesn't this work,

c.Select

then it's because you can't select a range on a sheet unless the sheet is selected.

The rest of the code should work just fine without Sheet1 being selected.

Not sure what you mean.

If you wanted to get the value of a cell/range that you have a reference to all you need is the reference, you don't need With, you don't need to select the sheet the range is on.

What are you trying to do in the first part of the code you posted?

It looks like you are trying to find every occurence of Vals in column A of Sheet1, but you don't seem to be doing anything else.

If there's only one occurence of Vals you don't need a loop or FindNext.

This should be all you need.

Private Sub ComboBox1_Change()
Dim Vals As String
Dim uCode As Integer

    uCode = 1234

    ' check something is selected in ComboBox1
    If accesscredentials.ComboBox1.ListIndex = -1 Then Exit Sub

    Vals = accesscredentials.ComboBox1.Value

    ' search for Vals in column A on Sheet1
    Set c = Sheets("Sheet1").Range("A:A").Find(Vals, LookIn:=xlValues)
    
    ' if Vals is found use range reference c to populate textboxes with appropriate data
    If Not c Is Nothing Then

        If ComboBox1 = "Applications" Then
            Me.TextBox1.Value = ""
            Me.TextBox2.Value = ""
            Me.TextBox3.Value = ""
            Me.TextBox4.Value = ""
        Else
            Me.TextBox1.Value = c.Offset(, 4).Value & vbCrLf & c.Offset(, 5).Value & vbCrLf & c.Offset(, 6).Value & vbCrLf & c.Offset(, 7).Value
            Me.TextBox2.Value = c.Offset(, 1).Value
            Me.TextBox4.Value = c.Offset(, 3).Value
            If Me.TextBox5.Value = uCode Then
                Me.TextBox3.Value = c.Offset(, 2).Value
            End If
        End If
    Else
        MsgBox Vals & " not found."
    End If
    
End Sub