How can I locate all cells with the same value and place specific text in adjacent cells

[taylormade]

I need a way to select a cell in a column, find all the cells with the same value, and place specific text in adjacent cells next to each of them.
For example, I select "Rite Aid" and for all cells containing "Rite Aid" I want to fill the cell next to it with "Prescriptions".
I'm brand new to Excel and I'm using the version that comes in Office 2010.
Please tell me what to do and how to implement it.

[millz]

Try running this macro.

In your Excel worksheet, press Alt + F11, this will open up the VB editor.
Press Ctrl + R to open up the Project explorer, displayed on the left by default.
Look for your workbook name, right click on it and Insert -> Module.
Now paste below code into the empty module window to the right side.
Go back to Excel worksheet, select the cell you wanted to find.
Press Alt + F8, to open up the macros window.
You should be able to see FindCellsPlaceText in there, run it.

Sub FindCellsPlaceText()
    Dim c As Range, f, addr, offs, s
    
    offs = -1   'this determines which cell next to the found cell
                ' -1 = cell to the left of found cell
                ' 1  = cell to the right of found cell
    s = "Prescriptions" 'the text to be entered
    
    f = ActiveCell.Value
    Set c = Cells.Find(f, lookat:=xlWhole)
    If Not c Is Nothing Then
        addr = c.Address
        Do
            c.Offset(, offs).Value = s
            Set c = Cells.FindNext(c)
            If c Is Nothing Then Exit Do
        Loop While c.Address <> addr
    End If
End Sub

[taylormade]

is there a way to mod it so that I'm prompted for the text (ie: Prescriptions) by way of a text box, rather than changing the actual code each time?

[taylormade]

yes, excellent. .thank you!

[millz]

Right, sorry I did not get an email notification of your last post, so I missed it somehow.

Sub FindCellsPlaceText()
    Dim c As Range, f, addr, offs, s
    
    offs = -1   'this determines which cell next to the found cell
                ' -1 = cell to the left of found cell
                ' 1  = cell to the right of found cell

    s = Application.InputBox("Please enter text to be placed beside found cells:", , "Prescriptions") 
    'the Prescriptions here now serves as the default value in the input box. remove if not needed
    
    f = ActiveCell.Value
    Set c = Cells.Find(f, lookat:=xlWhole)
    If Not c Is Nothing Then
        addr = c.Address
        Do
            c.Offset(, offs).Value = s
            Set c = Cells.FindNext(c)
            If c Is Nothing Then Exit Do
        Loop While c.Address <> addr
    End If
End Sub