concatenate dates into one string

Hii guys,

Need some help writing a VBA script for an access form. Please do help me out.
Here s what I have:

A access form that gives the start date(StrDate) and enddate(EndDate) for reporting.
I need to query the data base for records between these two dates but here is the catch.

The coulumn Month ( which I would like to query between StrDate and EndDate) is not in the date format.
It is in Text and has values such as "Q1 2006" or "2006-01-Jan" where 01 represents the month and not date.
So the month of February would be represented as "2006-02-Feb".
If the date was in the form Q1 then I know that I need to resolve the start date to "2006-01-Jan"

So This is what I would like to do :

write a function that takes the two dates, and concatenate all month in between as one string.
For example if the two dates are Q1 2006 and Q2 2006. The dates in between would be
"2006-01-Jan" , "2006-02-Feb", "2006-03-Mar" , "2006-4-Apr", "2006-5-May" and "2006-6-Jun"


How do i do this ?
Thank you guys for reading through this complex description.

Example

Sub test()
    MsgBox ConcDates("Q1 2006", "Q1 2006"), , "Q1 2006, Q1 2006"
    MsgBox ConcDates("2006-02-Feb", "2006-06-Jun"), , "2006-02-Feb, 2006-06-Jun"
    MsgBox ConcDates("2006-01-Jan", "Q3 2006"), , "2006-01-Jan, Q3 2006"
End Sub

Function ConcDates(ByVal txt1 As String, ByVal txt2 As String) As String
    Dim myYear As Long, myMonth As Long, myJoin As String
    Dim SDate As Date, EDate As Date, temp As Date, i As Long
    myJoin = Chr(34) & " , " & Chr(34)
    If txt1 Like "Q*" Then
        myMonth = Val(Replace(Split(txt1)(0), "Q", ""))
        myYear = Val(Split(txt1)(1))
    Else
        myYear = Val(txt1)
        myMonth = Val(Split(txt1, "-")(1))
    End If
    SDate = DateSerial(myYear, myMonth, 1)
    If txt2 Like "Q*" Then
        myMonth = Val(Replace(Split(txt2)(0), "Q", "")) * 3
        myYear = Val(Split(txt2)(1))
    Else
        myYear = Val(txt2)
        myMonth = Val(Split(txt2, "-")(1))
    End If
    EDate = DateSerial(myYear, myMonth, 1)
    Do
        temp = DateAdd("m", i, SDate)
        ConcDates = ConcDates & myJoin & Format$(temp, "yyyy-mm-mmm")
        i = i + 1
    Loop Until temp = EDate
    ConcDates = Mid$(ConcDates, Len(myJoin)) & """"
End Function