Fill a number of Merged cells with a Picture

Hi all,
I have a workbook that consists of 12 sheets, one for every month of the year. I want the user to be able to place a picture into a group of merged cells (W3 to Z10) in the January sheet. I found the following code, written by moonsaga on the forum. It works great but only puts the picture in the cell W3.

Sub InsertPicture()
Dim sPicture As String, pic As Picture
sPicture = Application.GetOpenFilename _
    ("Pictures (*.gif; *.jpg; *.bmp; *.tif), *.gif; *.jpg; *.bmp; *.tif", _
     , "Select Picture to Import")
 
If sPicture = "False" Then Exit Sub

Set pic = ActiveSheet.Pictures.Insert(sPicture)
With pic
    .ShapeRange.LockAspectRatio = msoFalse
    .Height = ActiveCell.Height
    .Width = ActiveCell.Width
    .Top = ActiveCell.Top
    .Left = ActiveCell.Left
    .Placement = xlMoveAndSize
End With
Set pic = Nothing
 
End Sub

I am new to VBA and don't even know what I want can be done.

Any advise would be appreciated.

Thanks.

Please take a few minutes to read the forum rules, and then edit your post to add CODE tags.

Thanks.

Thanks.

Try

Sub InsertPicture()
    Dim r           As Range
    Dim sPic        As String

    Set r = Range("W3:Z10")

    sPic = Application.GetOpenFilename(Filefilter:="Pictures (*.gif; *.jpg; *.bmp; *.tif), *.gif; *.jpg; *.bmp; *.tif", _
                                       Title:="Select Picture to Import")
    If sPic = "False" Then Exit Sub

    With ActiveSheet.Pictures.Insert(sPic)
        .ShapeRange.LockAspectRatio = msoFalse
        .Left = r.Left
        .Top = r.Top
        .Height = r.Height
        .Width = r.Width
        .Placement = xlMoveAndSize
    End With
End Sub

You're welcome.