Textbox ActiveX control as a search bar

Private Sub TextBox1_Change()

    ActiveSheet.ListObjects("Table13").Range.AutoFilter Field:=1, Criteria1:= _
                            "=*" & TextBox1.Text & "*", Operator:=xlAnd

End Sub

Thanks for the immediate response Andy. That's what exactly the function i'm looking however if you can expand selection and include all columns. The searchbox works only in Column B, but i want it to work on all columns only using the same one text box. Some examples:

1. If i typed "Jubail", it should show rows 5,4, and 29.
2. If i typed "EIS", rows 23 and 25 will show.
3. If i typed "X", rows 21 will show.

Also the search should not be limited only on the first characters. It should be in the middle of the last. Examples:

1. If i typed "ubai", it should show rows 5,4, and 29.
2. If i typed "IS-P", rows 23 and 25 will show.
3. If i typed "-MA", rows 21 will show.

Private Sub TextBox1_Change()

    Dim rngData As Range
    Dim rngFind As Range
    Dim rngFindAll As Range
    Dim strFirstAddress As String
    
    Set rngData = ActiveSheet.ListObjects("Table4").DataBodyRange
    
    ' unhide all
    rngData.EntireRow.Hidden = False
    If Len(TextBox1.Text) = 0 Then
        ' show all
    Else
        With rngData
            Set rngFind = .Cells.Find(TextBox1.Text, , xlValues, xlPart, , , False)
            If Not rngFind Is Nothing Then
                Set rngFindAll = rngFind.EntireRow
                strFirstAddress = rngFind.Address
                Do
                    Set rngFindAll = Union(rngFindAll, rngFind.EntireRow)
                    Set rngFind = .FindNext(rngFind)
                Loop While Not rngFind Is Nothing And strFirstAddress <> rngFind.Address
                .EntireRow.Hidden = True
                rngFindAll.EntireRow.Hidden = False
            End If
        End With
    End If

End Sub

Notice the table reference has changed. You have 3 tables on that sheet with overlapping ranges.

If you remove the overlapping tables and use a single table that encompasses all of the fields it will work.

Your original file had 3 tables defined.
Table13 $B$3:$G$29
Table3 $A$3:$A$29
Table4 $H$3:$M$29

Non of which completely covered all the data.

In the latest file I removed those tables and defined just on.
Table1 $A$3:$M$29

The date entry works for me. If I type in 15/o then row 29 only is displayed. You have to enter what is displayed in order to match records. 15/10 would not match with 15/Oct