Editing a text file from VBA

[MikeFranz123]

Hi,

I'm looking to clear all lines in a text file from VBA, starting from the second line.

From what I've seen so far it seems like the "fso" object is the way to go, but unfortunately I haven't found anyone doing what I'm trying to do exactly.

Anyone able to help?

Thanks!

Mike

[HaHoBe]

Hi, Mike ,

maybe you can start with a sample like this:

Sub EF972540()
Dim strPath As String
Dim strText As String
Dim intFile As Integer

Const cstrSAMPLE As String = "Sample.txt"

strPath = ThisWorkbook.Path & "\" & cstrSAMPLE
If Dir(strPath) = "" Then
  MsgBox "Couldnīt find '" & cstrSAMPLE & "'!"
  End
End If

intFile = FreeFile
Open strPath For Input As intFile
  Line Input #intFile, strText
Close

intFile = FreeFile
Open strPath For Output As intFile
  Print #intFile, strText
Close

End Sub

Ciao,
Holger

[millz]

Maybe this?

Sub EF972540_ClearTextFile()
    Dim fileName, toWrite As Variant
    Dim fd As Office.FileDialog
    Dim FS As FileSystemObject, a As TextStream
    
    Set fd = Application.FileDialog(msoFileDialogFilePicker)
    With fd
        .AllowMultiSelect = False
        .Title = "Select the text file"
        .Filters.Clear
        .Filters.Add "Text Files", "*.txt", 1
        If .Show = True Then
            fileName = .SelectedItems(1)
        Else
            Exit Sub
        End If
    End With
    
    Set FS = New FileSystemObject
    Set a = FS.OpenTextFile(fileName, 1)
    toWrite = a.ReadLine
    a.Close
    
    Set a = FS.CreateTextFile(fileName, True)
    a.WriteLine toWrite
    a.Close
    
    Set a = Nothing
    Set FS = Nothing
End Sub

[MikeFranz123]

Hi guys, thanks for the responses!

@Holger, I wasn't able to get your one to work for some reason, but @millz, yours worked perfectly.

Could you possibly explain what the code is doing?

Thanks again, both of you!

Mike

[millz]

A quick summary:
- Asks for text file
- Open the selected text file
- Read the first line of text, and store it in a variable
- Create a new blank text file with the same directory\file name. Original file is overwritten
- Writes that stored variable (first line of text) in the newly created text file

[MikeFranz123]

@millz, great, thanks so much!