Appending multiple excel sheets into one

Try this code

Option Explicit

Sub cons_data()

Dim Master As Workbook
Dim sourceBook As Workbook
Dim sourceData As Worksheet
Dim CurrentFileName As String
Dim myPath As String

Application.ScreenUpdating = False
Application.DisplayAlerts = False

'The folder containing the files to be recap'd
myPath = "D:\Storage"

'Finds the name of the first file of type .xls in the current directory
CurrentFileName = Dir(myPath & "\*.csv")

'Create a workbook for the recap report
Set Master = ThisWorkbook

Do
    Workbooks.Open (myPath & "\" & CurrentFileName)
    Set sourceBook = Workbooks(CurrentFileName)
    Set sourceData = sourceBook.Worksheets(1)
    
        With sourceData
            .Range("A2:K" & Range("A" & Rows.Count).End(xlUp).Row).Copy _
                    Master.Worksheets(1).Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
        End With
       
    sourceBook.Close (False)
  
'Calling DIR w/o argument finds the next .xlsx file within the current directory.
CurrentFileName = Dir()
Loop While CurrentFileName <> ""

MsgBox "Done"

Application.ScreenUpdating = True
Application.DisplayAlerts = True

End Sub

Copy the Excel VBA code
Select the workbook in which you want to store the Excel VBA code
Hold the Alt key, and press the F11 key, to open the Visual Basic Editor
Choose Insert | Module
Where the cursor is flashing, choose Edit | Paste

To run the Excel VBA code:
Choose Tools | Macro | Macros
Select a macro in the list, and click the Run button

Sorry for the delay in replying to you. I was sick for a week and couldnt get back to this thread.

Originally Posted by rexer231

Application.ScreenUpdating = False -> What does this do? - This stops the screen from flickering during the code execution. Once the code is complete, it will go back to the regular screen flickering as required.

Application.DisplayAlerts = False -> What does this do? This stops popups from showing up during code execution. Once the code is complete, it reverts to its original state.

CurrentFileName = Dir(myPath & "\*.csv") - > does this code ensure that xls, xlsx and csv are searched for? or is it just csv? Only csv since the line states *.csv.

Master.Worksheets(1).Range("A" & Rows.Count).End(xlUp).Offset(1, 0) - > what does offset(1,0) do? It asks the code to paste the data one row below the existing data. So offset (1,0) positions the pointer at the next available row.

putut,

If you have questions regarding those 2 functions, you can create a thread of your own and post it there. Someone, if not me, will surely help you.

Instead of

With sourceData
            .Range("A2:K" & Range("A" & Rows.Count).End(xlUp).Row).Copy _
                    Master.Worksheets(1).Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
        End With

use this

With sourceData
            .Range("A2:A" & Range("A" & Rows.Count).End(xlUp).Row).Copy _
                    Master.Worksheets(1).Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
            .Range("C2:C" & Range("C" & Rows.Count).End(xlUp).Row).Copy _
                    Master.Worksheets(1).Range("C" & Rows.Count).End(xlUp).Offset(1, 0)
            .Range("E2:E" & Range("E" & Rows.Count).End(xlUp).Row).Copy _
                    Master.Worksheets(1).Range("E" & Rows.Count).End(xlUp).Offset(1, 0)                  
        End With