Check if file is open on network without opening it

Hi, Alexander_Golinsky,

adapt the path and the name to suit:

Sub TestFileOpen()
   Dim iOpen As Integer
   Dim sFile As String
   Dim strPath As String
   
   strPath = "C:\Temp\"
   sFile = "your workbook.xlsm"
   If strPath & sFile = "" Then Exit Sub
   iOpen = TestOpen(strPath & sFile)
   Select Case iOpen
      Case 0: MsgBox "Workbook " & strPath & sFile & " is free"
      Case 1: MsgBox "The file is locked by " & GetFileOwner(strPath, sFile) & "."
      Case 2: MsgBox "Workbook " & strPath & sFile & " wasn´t found"
   End Select
End Sub

Private Function TestOpen(sPath As String) As Integer
   If Dir(sPath) = "" Then
      TestOpen = 2
   Else
      On Error GoTo ERRORHANDLER
      Open sPath For Random Access Read Lock Read Write As #1
      Close #1
   End If
ERRORHANDLER:
   If Err = 70 Then TestOpen = 1
End Function

Function GetFileOwner(fileDir As String, fileName As String) As String

'On Error Resume Next
Dim secUtil As Object
Dim secDesc As Object
Set secUtil = CreateObject("ADsSecurityUtility")
Set secDesc = secUtil.GetSecurityDescriptor(fileDir & fileName, 1, 1)
GetFileOwner = secDesc.owner
End Function

Ciao,
Holger