Delete dates not within a date range

Need to delete the dates before a start date
Need to delete the dates after a end date
Need help modifying the code below.

Start Date
8/14/2013
8/23/2013
8/23/2013
8/23/2013
9/1/2013
9/1/2013
9/5/2013
9/13/2013
9/20/2013
9/24/2013
9/29/2013

startdate = InputBox("Enter the start date of your date range in mm/dd/yy format")
mystartdate = CLng(startdate)
enddate = InputBox("Enter the end date of your date range in mm/dd/yy format")
myenddate = CLng(enddate)
myendrow = ActiveSheet.Range("F" & Rows.Count).End(xlUp).Row
For i = myendrow To 2 Step -1
If Cells(i, 1) < mystartdate And Cells(i, 1) > myenddate Then
Cells(F, 2).EntireRow.Delete
End If
Next i

End Sub

The "Test program Equipment Planner2.xls" transfer data from "PMData.xls"

Maybe

Sub RemoveDates()
Dim rng As Range
Dim dStart As Date
Dim dEnd As Date
dStart = CDate(Application.InputBox("Enter start date in format DD/MM/YYYY", "Start Date"))
dEnd = CDate(Application.InputBox("Enter end date in format DD/MM/YYYY"))
If IsDate(dStart) = False Or IsDate(dEnd) = False Then
    MsgBox "You did not enter date in correct format, please try again."
    Exit Sub
End If
For Each rng In Range("A2:A" & Range("A" & Rows.Count).End(xlUp).Row)
    If CDate(rng.Value) < dStart Or CDate(rng.Value) > dEnd Then
        rng.EntireRow.Delete
    End If
Next rng

End Sub

Hello,

Try this code :

Sub test()
   Dim startdate As String
   Dim enddate As String
   Dim mystartdate As Long
   Dim myenddate As Long
   Dim myendrow As Long
   Dim i As Long

   startdate = InputBox("Enter the start date of your date range in mm/dd/yy format")
   mystartdate = CDate(startdate)
   enddate = InputBox("Enter the end date of your date range in mm/dd/yy format")
   myenddate = CDate(enddate)
   myendrow = ActiveSheet.Range("F" & Rows.Count).End(xlUp).Row
   For i = myendrow To 2 Step -1
      If CDate(Cells(i, 1)) < mystartdate Or CDate(Cells(i, 1)) > myenddate Then
         Rows(i).EntireRow.Delete
      End If
   Next i

End Sub

Reminder : As per forum rules. Please use code tags to make your code visible.

Yet one more:

Sub Delete_Excluded_Dates()
    
    Dim LastRow As Long, strDate As String, lStart As Long, lEnd As Long
    
    LastRow = Range("F" & Rows.Count).End(xlUp).Row
    
    Do
        strDate = Application.InputBox("Enter the start date of your date range in mm/dd/yy format", "Start Date", Type:=2)
        If strDate = "False" Then Exit Sub  'User canceled
        If IsDate(strDate) Then Exit Do
        MsgBox "Invalid date entry. ", , "Invalid Entry"
    Loop
    lStart = CDate(strDate)
    
    Do
        strDate = Application.InputBox("Enter the end date of your date range in mm/dd/yy format", "End Date", Type:=2)
        If strDate = "False" Then Exit Sub  'User canceled
        If IsDate(strDate) Then Exit Do
        MsgBox "Invalid date entry. ", , "Invalid Entry"
    Loop
    lEnd = CDate(strDate)
    
    Application.ScreenUpdating = False
    Range("F1:F" & LastRow).AutoFilter 1, "<" & lStart, xlOr, ">" & lEnd
    Range("F2:F" & LastRow).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    ActiveSheet.AutoFilterMode = False
    Application.ScreenUpdating = True
    
End Sub

Thank you AlphaFrog

When I run the I get a "runtime error 1004" at this line

"Range("F2:F" & LastRow).SpecialCells(xlCellTypeVisible).EntireRow.Delete".

I have attach my files to this thread.

Originally Posted by BowHunter09

Thank you AlphaFrog

When I run the I get a "runtime error 1004" at this line

"Range("F2:F" & LastRow).SpecialCells(xlCellTypeVisible).EntireRow.Delete".

I have attach my files to this thread.

Try this...

    Application.ScreenUpdating = False
    ActiveSheet.AutoFilterMode = False
    Range("F1:F" & LastRow).AutoFilter 1, "<" & lStart, xlOr, ">=" & lEnd + 1
    Range("F2:F" & LastRow).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    ActiveSheet.AutoFilterMode = False
    Application.ScreenUpdating = True

@BowHunter09

Your post does not comply with Rule 3 of our Forum RULES. Use code tags around code.

Posting code between [CODE] [/CODE] tags makes your code much easier to read and copy for testing, it also maintains VBA formatting.

Highlight your code and click the # icon at the top of your post window. More information about these and other tags can be found here



(I have added them for you this time. Please read all the forum rules and observe them in the future.)