Sort for multicolumn listbox in userform (5-columns)

This will do it for any number of columns.

Private Sub m_SortListbox(OnColumn As Long)

    Dim vntData As Variant
    Dim vntTempItem As Variant
    Dim lngOuterIndex As Long
    Dim lngInnerIndex As Long
    Dim lngSubItemIndex As Long
    
    'Store the list in an array for sorting
    vntData = Me.ListBox1.List
     
     'Bubble sort the array on the first value
    For lngOuterIndex = LBound(vntData, 1) To UBound(vntData, 1) - 1
         For lngInnerIndex = lngOuterIndex + 1 To UBound(vntData, 1)
             If vntData(lngOuterIndex, OnColumn) > vntData(lngInnerIndex, OnColumn) Then
                'Swap values
                For lngSubItemIndex = 0 To ListBox1.ColumnCount - 1
                    vntTempItem = vntData(lngOuterIndex, lngSubItemIndex)
                    vntData(lngOuterIndex, lngSubItemIndex) = vntData(lngInnerIndex, lngSubItemIndex)
                    vntData(lngInnerIndex, lngSubItemIndex) = vntTempItem
                Next
             End If
         Next lngInnerIndex
     Next lngOuterIndex
     
     'Remove the contents of the listbox
    Me.ListBox1.Clear
     'Repopulate with the sorted list
    Me.ListBox1.List = vntData

End Sub

Yes it does. That is what the SortOn argument in the subs signature is.

This example will sort the column you double click.

Kem60,
Unfortunately your post does not comply with Rule 2 of our Forum RULES. Do not post a question in the thread of another member -- start your own thread.

If you feel an existing thread is particularly relevant to your need, provide a link to the other thread in your new thread.

Old threads are often only monitored by the original participants. New threads not only open you up to all possible participants again, they typically get faster response, too.

The sort is a bubble sort based on the textual content. In order to sort the dates properly you will need to sort their numeric values rather than the text in m/d/yyyy format.

I have added a extra column, which you can hide using ColumnWidth of zero. When the 2nd column is sorted it uses the extra column values to actually sort on.

Originally Posted by Andy Pope

The sort is a bubble sort based .

first off all very nice work-a-round idea

i am learning userforms by looking at examples and solutions

in looking at this example 964420 i not that allthough it does everything OP required. for me it does not display the first row of your data sheet in the userform

maybe i am doing something wrong

regards

@AkaTrouble. In order to display header in a listbox you need to use the rowsource property. This links the listbox directly with cells on the worksheet with the header row being the row immediately above the data. In order to sort the listbox you will need to sort the worksheet.