VBA Code to copy data from one sheet and paste to multiple other sheets

In the attached file I have a macro that will copy the data entered in B3:F3 and paste it into a range below depending on what is selected in C4. This code works great, however I want to see if I can have a stand alone data entry sheet (Multi-Add) that when the button is clicked it will copy the data on that sheet and paste it into every other sheet in the work book but again based on the "Type" selected in C4.

The final thing I want to do is in the "General" and "Specialist" ranges - when there is no data in the row I would like the row to be hidden and then when data is added through the above it would un-hide.

Any help on this would be great, thank you.

Try something like this...

Option Explicit
Sub Post_ItAll()
    
    Dim cel As Range
    Dim NR As Long
    Dim ws As Worksheet
    Dim strType As String
    
    For Each cel In Range("B3:F3")
        If cel.Value = "" Then
            MsgBox "Missing Data"
            Range(cel.Address).Activate
            Application.EnableEvents = False
            Range("C4").Value = ""
            Application.EnableEvents = True
            Exit Sub
        End If
    Next cel
    
    strType = Range("C4").Value
        
    For Each ws In Worksheets
        If ws.Name Like "Agent*" Then
            With ws.Range(strType).Resize(, 1)
                NR = Application.CountA(.Cells) + 1
                If NR > .Rows.Count Then
                    MsgBox "The '" & strType & "' range on sheet '" & ws.Name & "' is full. ", , "Copy Canceled"
                Else
                    .Cells(NR).Resize(, 5).Value = ActiveSheet.Range("B3:F3").Value
                    .Cells.EntireRow.Hidden = True
                    .Cells.Resize(NR).EntireRow.Hidden = False
                End If
            End With
        End If
    Next ws
    
    MsgBox "Post It complete. "
    
End Sub

Originally Posted by JimmyG.

Thanks Alphafrog that works great, which part of that code would I copy into the existing code on the attached book to achieve the hidden/show row execution?
Thanks, James

You're welcome.

All of it. Replace your previous Post_ItAll procedure with this new one. I'm confused though. If it "works great", apparently you already implemented the new code properly.

Sub Post_It()
    
    Dim cel As Range
    Dim NR As Long
    Dim strType As String
    
    For Each cel In Range("B3:F3")
        If cel.Value = "" Then
            MsgBox "Missing Data ", vbExclamation, "Invalid Entry"
            Range(cel.Address).Activate
            Application.EnableEvents = False
            Range("C4").Value = ""
            Application.EnableEvents = True
            Exit Sub
        End If
    Next cel
    
    strType = Range("C4").Value
        
    With Range(strType).Resize(, 1)
        NR = Application.CountA(.Cells) + 1
        If NR > .Rows.Count Then
            MsgBox "The '" & strType & "' range is full. ", , "Copy Canceled"
        Else
            .Cells(NR).Resize(, 5).Value = Range("B3:F3").Value
            .Cells.EntireRow.Hidden = True
            .Cells.Resize(NR).EntireRow.Hidden = False
        End If
    End With
    
End Sub