Replace value of cells in sheet1 with list of values in sheet2 identified by sheet1 value

I am looking for a macro to place on an Excel sheet that would replace all values in a range of columns that have a corresponding list of values in another worksheet that each have the same identifier. So Sheet1 contains several columns with various values.

A B C D
1 PRD LFT DEC
2 DEC STF PRD

Sheet2 contains 2 columns. In Column1 there are values that correspond to some of the values
A B
1 PRD test1
2 PRD test2
3 PRD test3
4 DEC sys1
5 DEC sys2

Clicking on the macro button would replace PRD in A1 & C2 in Sheet1 with "test1, test2, test3" and DEC in D1 & A2 with "sys1, sys2" and so on for all values that exist in Sheet 2. There could be values in Sheet1, like LFT, that do not exist in Sheet2 so these would be skipped

Solved using the following:

Sub ReplaceCodes()
Dim cel As Range
Dim strCode As String
Dim rngFound As Range
Dim strAddress As String
Dim strReturn As String
Application.ScreenUpdating = False
For Each cel In Worksheets("Sheet1").UsedRange ' or a specific range
strCode = cel.Value
If strCode <> "" Then
With Worksheets("Sheet2").Range("A:A")
Set rngFound = .Find(What:=strCode, LookAt:=xlWhole, _
After:=.Cells(.Cells.Count))
If Not rngFound Is Nothing Then
strReturn = rngFound.Offset(ColumnOffset:=1).Value
strAddress = rngFound.Address
Do
Set rngFound = .FindNext(After:=rngFound)
If rngFound.Address = strAddress Then Exit Do
strReturn = strReturn & ", " & _
rngFound.Offset(ColumnOffset:=1).Value
Loop
cel.Value = strReturn
End If
End With
End If
Next cel
Application.ScreenUpdating = True
End Sub