Quicker way to loop through WorksheetFunction?

Any chance of posting a copy of your workbook?

Please try

Public Sub recordLastMonthMilage()

'#
'# declare private variables
'#
   Dim pvt_xls_LastMonth As Excel.Worksheet
   Dim pvt_dct_LastMonth As Object
   Dim pvt_lng_RowNumber As Long
   
'#
'# initialise
'#
   Set pvt_xls_LastMonth = ThisWorkbook.Worksheets("Last Month Data")
   Set pvt_dct_LastMonth = CreateObject("Scripting.Dictionary")

'#
'# build a dictionary holding the milage of last month per car registration
'#
   With pvt_xls_LastMonth
      For pvt_lng_RowNumber = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row
         If Not pvt_dct_LastMonth.Exists(.Cells(pvt_lng_RowNumber, "A").Value) Then
            pvt_dct_LastMonth.Add .Cells(pvt_lng_RowNumber, "A").Value, .Cells(pvt_lng_RowNumber, "B").Value
         End If
      Next pvt_lng_RowNumber
   End With
   
'#
'# for each registration of the current month worksheet retrieve the milage submitted in the previous
'# month and record the difference in column 12
'#
   With ThisWorkbook.Worksheets("Current Month Data")
      For pvt_lng_RowNumber = 2 To .Cells(.Rows.Count, "A").End(xlUp).Row
         If Not pvt_dct_LastMonth.Exists(.Cells(pvt_lng_RowNumber, "A").Value) Then
            .Cells(pvt_lng_RowNumber, "L").Value = "NEW ?"
         Else
            .Cells(pvt_lng_RowNumber, "L").Value = .Cells(pvt_lng_RowNumber, "B").Value - pvt_dct_LastMonth(.Cells(pvt_lng_RowNumber, "A").Value)
         End If
      Next pvt_lng_RowNumber
   End With

'#
'# housekeeping
'#
   Set pvt_dct_LastMonth = Nothing
   
End Sub

I was in a meeting at work. Will have a look

or, using a different approach

Public Sub recordLastMonthMilageUsingADO()

   '#
   '# declare private variables
   '#
      Dim pvt_obj_Connection As Object
      Dim pvt_obj_Recordset As Object
      Dim pvt_str_Query As String

      Const adOpenDynamic As Long = 2
      Const adLockReadOnly As Long = 1
   
   '#
   '# perform a LEFT JOIN on registration codes, subtracting the milage of last month from the
   '# milage of the current month where the registration codes match
   '#
      pvt_str_Query = "SELECT [S1].[Mileage Submitted] - [S2].[Mileage Submitted] " & _
                     "   FROM [Current Month Data$] AS S1 LEFT JOIN [Last Month Data$] AS S2 " & _
                     "     ON [S1].[Registration Submitted] = [S2].[Registration Submitted];"
   '#
   '# get data
   '#
      Set pvt_obj_Connection = CreateObject("ADODB.Connection")
      With pvt_obj_Connection
         .Provider = "Microsoft.Jet.OLEDB.4.0"
         .ConnectionString = "Data Source='" & ThisWorkbook.Path & "\" & ThisWorkbook.Name & "'; " & "Extended Properties=Excel 8.0"
         .Open
      End With
      
      Set pvt_obj_Recordset = CreateObject("ADODB.Recordset")
      pvt_obj_Recordset.Open pvt_str_Query, pvt_obj_Connection, adOpenDynamic, adLockReadOnly
      
      ThisWorkbook.Worksheets("Current Month Data").Range("L2").CopyFromRecordset pvt_obj_Recordset
   
   '#
   '# housekeeping
   '#
      pvt_obj_Recordset.Close
      pvt_obj_Connection.Close
                     
   End Sub