Print off the word document using excel vba code

**aman1234** · 09-17-2013, 09:13 AM

Hi there

I have a userform and there is a textbox which ask the user to type the name of word document. I want to write the code so that when the user type the word document name and press print button then it should print off the word document which is stored in "J\ABC\xxx\Test" automatically. if that word file is not present in the folder mentioned then just display an error message "The file doesn't exist"

I hope anyone can help me out in this.

Thanks

**OllieB** · 09-17-2013, 09:42 AM

aman,

create a module in your excel workbook and add the following code

Public Sub printWordDocument()
On Error Resume Next

'#
'# declare private variables
'#
   Dim objWordApplication As Object
   Dim objDocument As Object
   Dim strDocumentName As String
   
   Const wdPrintAllDocument As Integer = 0
   Const wdPrintDocumentWithMarkup As Integer = 7
   Const wdPrintAllPages As Integer = 0
   
'#
'# get the document name specified by the user from cell A1 on the worksheet named
'# 'Sheet1' - modify to meet your requirements
'#
   strDocumentName = ThisWorkbook.Worksheets("Sheet1").Range("A1").Value
   
'#
'# open the document specified by the user
'#
   Set objWordApplication = CreateObject("Word.Application")
   Set objDocument = objWordApplication.Documents.Open("J:\ABC\xxx\" & strDocumentName)
   
   If objDocument Is Nothing Then
      MsgBox "Sorry but document " & Chr$(34) & strDocumentName & Chr$(34) & " cannot be found"
      objWordApplication.Quit
      Set objDocument = Nothing
      Set objWordApplication = Nothing
      Exit Sub
   End If
   
'#
'# print the document
'#
   objDocument.PrintOut Range:=wdPrintAllDocument, Item:=wdPrintDocumentWithMarkup, Copies:=1, Pages:="", PageType:= _
      wdPrintAllPages, Collate:=True, Background:=True, PrintToFile:=False, PrintZoomColumn:=0, PrintZoomRow:=0, PrintZoomPaperWidth:=0, _
      PrintZoomPaperHeight:=0

'#
'# housekeeping
'#
   objDocument.Close
   objWordApplication.Quit
   Set objDocument = Nothing
   Set objWordApplication = Nothing

End Sub

add a button to the worksheet where the user will specify the document name and link the button to the above routine. In the example code provided change the cell reference to the one where the user will be specifying the document name