How to move entire rows if a condition is met

Hi all,

I need a vba code that can move an entire row if a condition in column G is met. I've seen some similar things on here, but they have a number condition, usually if "0" is in a cell, to be met. However, what I will need is it to recognize text and sort due to that. In column G, either "Information", "Budget", or "Quote" will be entered. If "Information" is entered, it will go to a tab called unqualified leads. If it is "Budget" or "Quote" then it will go to a tab called qualified leads. Thanks in advance for all your help.

Try:

Sub RunMe()
Dim ws1 As Worksheet:   Set ws1 = Sheets("Sheet1") 'this is you main sheet.  You may need to change this to match
Dim ws2 As Worksheet:   Set ws2 = Sheets("unqualified leads")
Dim ws3 As Worksheet:   Set ws3 = Sheets("qualified leads")
Dim icell As Long

Application.ScreenUpdating = False

For icell = ws1.Range("G" & Rows.Count).End(xlUp).Row To 1 Step -1
    Select Case ws1.Range("G" & icell).Value
        Case Is = "Information"
            ws1.Range("A" & icell).EntireRow.Copy Destination:=ws2.Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
            ws1.Range("A" & icell).EntireRow.Delete Shift:=xlUp
        Case Is = "Budget", "Quote"
            ws1.Range("A" & icell).EntireRow.Copy Destination:=ws3.Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
            ws1.Range("A" & icell).EntireRow.Delete Shift:=xlUp
        Case Else
    End Select
Next icell

Application.ScreenUpdating = True

End Sub

Maybe:

Private Sub Worksheet_Change(ByVal Target As Range)
If Not Intersect(Target, Range("G2:G" & ActiveSheet.UsedRange.Rows.Count + 1)) Is Nothing Then
    Select Case Target.Value
    Case Is = "Information"
        Target.EntireRow.Copy Sheets("unqualified leads").Range("A" & Rows.Count).End(3)(2)
    Case Is = "Budget", "Quote"
        Target.EntireRow.Copy Sheets("qualified leads").Range("A" & Rows.Count).End(3)(2)
    End Select
End If
end sub

Thank you so much to everyone who replied! I tried both codes and couldn't get yours to work John. Stnkynts I did get yours to work. Tony thanks for the help but i needed more in depth help as I am fairly new with VBA. Thanks again everyone!

The code I posted is for a Worksheet Event and should be placed in the Sheet Module.