If/Then statement to copy/paste range of cells

I am trying to copy/paste a range of cells if a particular cell is equal to the cell below it.

In the attached file I am going for something like:
If B3 = B2, then copy C2:I2 , paste in C3:I3.
repeat all of the way down

I use the following code a good bit and have tried to manipulate it in different ways to get the desired result, but have not had any success. I realize this code below starts at the bottom and works up and I could do that as well if I sorted the attached spreadsheet by ascending column B, ascending column A (instead of descending as it is now)

 Dim i, LastRow
    LastRow = Range("G" & Rows.Count).End(xlUp).Row
    For i = LastRow To 5 Step -1
    If Cells(i, "G").Value = "0" Then
    Cells(i, "G").EntireRow.Delete
    End If
    Next

thank you!

Does this work for your needs?

Sub RunME()
Dim ws As Worksheet:    Set ws = Sheets("Master")
Dim icell As Range

Application.ScreenUpdating = False
For Each icell In ws.Range("B2:B" & ws.Range("B" & Rows.Count).End(xlUp).Row)
    If icell.Value = icell.Offset(1, 0).Value Then
        icell.Offset(0, 1).Resize(1, 7).Copy Destination:=icell.Offset(1, 1)
    End If
Next icell
Application.ScreenUpdating = True

End Sub

Another:

Sub lacticacidbath()
Application.ScreenUpdating = False
Range("B2").Select
Do Until ActiveCell.Value = ""
    If ActiveCell.Value = ActiveCell.Offset(1).Value Then
        Range(ActiveCell.Offset(, 1), ActiveCell.Offset(, 7)).Copy ActiveCell.Offset(1, 1)
    End If
    ActiveCell.Offset(1).Select
Loop
Application.ScreenUpdating = True
End Sub

Another good one as well. Among other things, I made the mistake playing with the ActiveCell.FormulaR1C1 format instead of just using the easier ActiveCell.Offset.

Thank you!

This is perfect! Thank you!