Show data which rows are not hidden

Hi!

Try this code in the DropButtonClick event of your combo box:

Private Sub ComboBox1_DropButtonClick()
    Dim i As Long
    Dim startRow
    Dim strCol
    
    'Enter the starting row of your data for the list
    startRow = 1
    'Enter the column letter of the column containing your list data
    strCol = "A"
    
    ComboBox1.Clear
    
    With Worksheets("Sheet1")
        For i = startRow To .Cells(.Rows.Count, strCol).End(xlUp).Row
            If Not .Rows(i).Hidden Then
                ComboBox1.AddItem .Cells(i, strCol).Value
            End If
        Next i
    End With
End Sub

I hope this helps you

Thanks Ajryan88. It works almost 98%. I am looking in to this to make it 100%. Duplicates is appearing in the list, trying to remove it.

Thanks again.

Hi,

Try changing

If Not .Rows(i).Hidden Then
    ComboBox1.AddItem .Cells(i, strCol).Value
End If

to

If Not .Rows(i).Hidden Then
    blnExist = False
    
    For j = 0 To ComboBox1.ListCount - 1
        If ComboBox1.List(j) = .Cells(i, strCol).Value Then
            blnExist = True
            Exit For
        End If
    Next j
    
    If Not blnExist Then
        ComboBox1.AddItem .Cells(i, strCol).Value
    End If
    
    blnExist = False
End If

and you will have to declare the following variables at the top of the code with the rest of the declarations:

Dim j As Long
Dim blnExist As Boolean

Hope this gets it to 100%