ScreenUpdate does not work with a macro that activates different workbooks

Hi,
I have a code that matches hidden columns in 2 different workbooks. It is a part of a UserForm that activates different processes and I couldn't avoid activating the workbooks.
Eventhough I use Application.ScreeUpdating = False the screen still flickers. Is there any trick I might use to avoid it? Thanks in advance!

Private Sub MatchColumns()
Dim sFilePath As String
Dim tFilePath As String
Dim SourceFile As String
Dim TargetFile As String
Dim SourceActivetab As String
Dim TargetActivetab As String
Dim i As Integer
Dim x As Integer
    
Application.ScreenUpdating = False
    SourceActivetab = ComboBox1.Value
    TargetActivetab = ComboBox2.Value
  
    sFilePath = Left(TextBox1.Value, InStrRev(TextBox1.Value, ".", -1) - 1)
    SourceFile = Right(sFilePath, Len(sFilePath) - InStrRev(sFilePath, "\"))
    tFilePath = Left(TextBox2.Value, InStrRev(TextBox2.Value, ".", -1) - 1)
    TargetFile = Right(tFilePath, Len(tFilePath) - InStrRev(tFilePath, "\"))
    
    Application.Workbooks(TargetFile).Activate
    ActiveWorkbook.Worksheets(TargetActivetab).Activate
    Cells.Select
    Selection.EntireColumn.Hidden = False
    
    Application.Workbooks(SourceFile).Activate
    ActiveWorkbook.Worksheets(SourceActivetab).Activate
    
For i = 1 To ActiveWorkbook.ActiveSheet.UsedRange.Columns.Count

    If ActiveWorkbook.ActiveSheet.Columns(i).Hidden = True Then
       Application.Workbooks(TargetFile).Activate
       ActiveWorkbook.Worksheets(TargetActivetab).Activate
       ActiveWorkbook.ActiveSheet.Columns(i).Hidden = True
       Else: ActiveWorkbook.ActiveSheet.Columns(i).Hidden = False
    End If
    Application.Workbooks(SourceFile).Activate
    ActiveWorkbook.Worksheets(SourceActivetab).Activate
Next i
Application.ScreenUpdating = True
End Sub

try something like this (not tested).

Private Sub MatchColumns()
    
    Dim SourceFile As String
    Dim TargetFile As String
    Dim wsSource   As Worksheet
    Dim wsTarget   As Worksheet
    Dim i          As Long
    
    SourceFile = Left(TextBox1.Value, InStrRev(TextBox1.Value, ".", -1) - 1)
    SourceFile = Right(SourceFile, Len(SourceFile) - InStrRev(SourceFile, "\"))
    
    TargetFile = Left(TextBox2.Value, InStrRev(TextBox2.Value, ".", -1) - 1)
    TargetFile = Right(TargetFile, Len(TargetFile) - InStrRev(TargetFile, "\"))
    
    Set wsSource = Application.Workbooks(SourceFile).Worksheets(ComboBox1.Value)
    Set wsTarget = Application.Workbooks(TargetFile).Worksheets(ComboBox2.Value)
    
    Application.ScreenUpdating = False
    
    wsTarget.Columns.Hidden = False
    
    For i = 1 To wsSource.UsedRange.Columns.Count
        wsTarget.Columns(i).Hidden = wsSource.Columns(i).Hidden
    Next i
    
    Application.ScreenUpdating = True
    
End Sub

Thanks! I will check it out.