If Or statement to check cell text and delete entire row if text is found

I'm having a little trouble getting this sorted. In column A I have a list of letters: A, B, D, M and N. I need to loop through each cell, and delete all rows that contain B, M, N, as well as blanks. Here's my code:

Sub Main()
Dim lastrow As Double
lastrow = ActiveSheet.Cells(Rows.Count, "A").End(xlUp).Row

For Each cell In ThisWorkbook.ActiveSheet.Range("A1:A" & lastrow)
    If cell.Text = "B" Or cell.Text = "M" Or cell.Text = "N" Or cell.Text = "" Then
    cell.EntireRow.Delete
    End If
Next cell

End Sub

My problem here is this isn't deleting the rows that contain the letter N. If I run the macro, it deletes rows that contain B, M, and blanks, and then if I run it a second time, it WILL delete the rows containing the letter N. Any ideas on what's going on here? I've attached a workbook with the code contained in a module. Thanks

Sub Main()
Dim lastrow As Double
lastrow = ActiveSheet.Cells(Rows.Count, "A").End(xlUp).Row

For r = lastrow to 1 step -1
    If cells(r,1).Text = "B" Or cells(r,1).Text = "M" Or cells(r,1).Text = "N" Or cells(r,1).Text = "" Then
      rows(r).Delete
    End If
Next

End Sub

Alternate version...

Sub Main()
    
    Dim ACell As Range
    Dim rngDel As Range
    
    For Each ACell In Range("A1", Cells(Rows.Count, "A").End(xlUp)).Cells
        Select Case ACell.Text
            Case "B", "M", "N", ""
                If rngDel Is Nothing Then Set rngDel = ACell Else Set rngDel = Union(rngDel, ACell)
        End Select
    Next ACell
    
    If Not rngDel Is Nothing Then rngDel.EntireRow.Delete
    
    Set ACell = Nothing
    Set rngDel = Nothing
    
End Sub