Select entire row based on data validation selection

Hi guys,

I have a simple table with distances between Italian cities. dist.xlsx

What I'm trying to have is when a user chooses a starting point (A14 - validated list), cell B14 will show a destination location that is the closest to the selection in A14, based on the data from the table.

Now I thought that I could simply use the MIN formula to check which value in a row is the lowest, then copy the heading (B2:H2) of that value into B14. But how to tell VBA to select the entire row in which the starting city is located in the first place? So, say a user chooses the city Inveruno in A14. Then after hitting the macro button, cell B14 would output the city Arluno, which is at 10 km from Inveruno.

I'm not new to VBA (let's say pre-intermidiary), but I just can't seem to figure this out...

Hi mintymike

This Code is in the attached and appears to do as you require. Please note, in the event of ties it picks the first.

Option Explicit
Private Sub Worksheet_Change(ByVal Target As Range)
    Dim ColNo As String
    Dim myCol As String
    Dim FindString As String
    Dim rng As Range
    If Target.Cells.Count > 1 Or IsEmpty(Target) Then Exit Sub
    If Target.Address = "$A$14" Then
        FindString = Range("A14").Value
        With Sheets("Sheet1").Range("A:A")
            Set rng = .Find(What:=FindString, _
                    After:=.Cells(.Cells.Count), _
                    LookIn:=xlValues, _
                    LookAt:=xlWhole, _
                    SearchOrder:=xlByRows, _
                    SearchDirection:=xlNext, _
                    MatchCase:=False)
            If Not rng Is Nothing Then
                ColNo = MinAddress(Range(Cells(rng.Row, 1), Cells(rng.Row, 8)))
            End If
        End With
        myCol = Split(ColNo, "$")(1)
        Application.EnableEvents = False
        Range("B14").Value = Cells(2, myCol).Value
        Application.EnableEvents = True
    End If
End Sub
'From http://support.microsoft.com/kb/139574
Function MinAddress(The_Range)
    Dim MinNum As Long
    Dim cell As Range
    ' Sets variable equal to minimum value in the input range.
    MinNum = Application.Min(The_Range)
    ' Loop to check each cell in the input range to see if equals the
    ' min variable.
    For Each cell In The_Range
        If cell = MinNum Then
            ' If the cell value equals the max variable it
            ' returns the address to the function and exits the loop
            MinAddress = cell.Address
            Exit For
        End If
    Next cell
End Function

Hi John,

wow, that's awesome!! It does exactly what I wanted!! Not sure if I can ask about one more thing in this thread or should I start a new one, but... Using the excel above and your code, is there a way of adding another header in C13, called something like Nearest destination 2 and have the code input in C14 a city name that would be second closest? I know this might be complicated, so let me give an example.

I can't reuse your code for cell C14, because if the code finds the closest location, and if we choose ie. Arluno, your code will show in B14 Inveruno as the closest - and it is correct. But then if we wanted to use the code again in C14, it would again show Arluno - because it is the closest one to Inveruno. And I'd like to choose Arluno and have the VBA show me: B14 - Inveruno, C14 - Gaggiano (because this one is the closest to Inveruno, not counting Arluno).

If I should start a new thread and mark this one as SOLVED, just let me know and I'll do so. Thanks for the commitment so far.

Hi mintymike

Could have swore I posted this the other day...ah well

You're welcome...glad I could help. Thanks for the Rep.