Filter Listbox Values based on Textbox input

Would you like it case sensitive or case insensitive?

Assuming lowercase:

Option Explicit
Dim h() As String

Private Sub Search1_Change()

    Dim temp, temp2, i As Long
    
    temp = Filter(h, LCase(Me.Search1.Text))
    
    If UBound(temp) <> -1 Then
        ReDim temp2(UBound(temp))
        For i = LBound(temp) To UBound(temp)
            temp2(i) = Split(temp(i), vbCrLf)(UBound(Split(temp(i), vbCrLf)))
        Next i
        Me.LboSearch.List = temp2
    Else
        Me.LboSearch.Clear
    End If
    
End Sub
Private Sub UserForm_Initialize()

Dim g() As Variant

Dim i As Long, j As Long

g = Sheet1.ListObjects("contact").Range.Value

ReDim h(LBound(g) To UBound(g) - 1)
For i = LBound(g) To UBound(g) - 1
    For j = LBound(g, 2) To UBound(g, 2)
        h(i) = h(i) & vbCrLf & LCase(g(i + 1, j))
    Next j
Next i
End Sub

It stops being perfectly smooth at around 10k rows on my machine, but it's still very useable - I've tested it up to 30k rows

Thanks!

I cracked the nut myself (just 1 minute ago) using the below code. Any comments on this solution are welcome. I am eager to learn

Private Sub Search1_Change()

Dim search As Variant
Dim c As Variant
Dim firstaddress As Variant
Dim item As Variant
Dim result As Variant
Dim match As Integer


On Error GoTo skip
match = 0
LboSearch.Clear

With Range("Contact")
    Set c = .Find(Search1, LookIn:=xlValues, lookat:=xlPart)
    If Not c Is Nothing Then
        firstaddress = c.Address
        Do
            result = Sheets("Contact").Cells(Range(c.Address).Row, 11).Value
            For Each item In LboSearch.List
                If item = result Then match = 1
            Next item
            If match = 0 Then LboSearch.AddItem result
            Set c = .FindNext(c)
            match = 0
        Loop While Not c Is Nothing And c.Address <> firstaddress
    End If
End With

skip:
End Sub

Your code is solid enough , but will get very slow with a lot of entries. Try dragging your data down to about 10k rows - if you never have many the it's not a problem though

Tried it with 20k rows and yes.... it becomes very slow indeed.

I dont expect to have more than 1k of rows though.

Thanks for your input!