Alert prompt if date and time is reached

So in a sheet called Sims, I want to be prompted automatically if the date in cell D2 and the time in E2 have both passed. If they have passed I ideally would like an email to be automatically sent to an address saying this. My outlook will always be open for this. Ideally the subject would be whatever is contained in cell A2 and 'needs looking at'. So if cell A2 said Tigers, and the date and time were both in the past then an email would be sent with the subject 'Tigers needs looking at'.

There will also be dates and times all the way down to row 20 and the same will need to happen for those. So the macro would check which rows meet the criteria and then send an email each time the criteria are met.

Change

.Subject = Range("A2") & " needs looking at"

to

.Subject = Range("A" & i) & " needs looking at"

I think the code opens up a new instance of outlook anyway. It shouldn't matter if outlook is open or not.

add

Range("F" & i) = "SENT"

and put an if statement along the lines of:

if not Range("F" & i) = "SENT" then
   'code here
end if

since it's two different macros though, won't I need something like Sub emailHim(ByVal x as Integer) so the macro that actually sends the email knows which cell to use when populating the subject line?

Sorry I missed it was two separate macros. Probably need this:

Sub emailTiger()
Dim dateRow As Integer
dateRow = Range("D2").End(xlDown).Row
For i = 2 To dateRow
    If Range("D" & i).Value < Date And Not Range("F" & i) = "SENT" Then
        Call emailHim(i)
    End If
    
    If Range("D" & i).Value = Date And Range("E" & i).Value < Time And Not Range("F" & i) = "SENT" Then
        Call emailHim(i)
    End If
Next i
End Sub

Sub emailHim(i)
    Dim OutApp  As Object
    Dim OutMail  As Object
    
    On Error GoTo errorKey
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    
    On Error Resume Next
    With OutMail
        .Subject = Range("A" & i) & " needs looking at"
        .Body = "Body Text"
        .Recipients.Add ("your email address")
        .Recipients.ResolveAll
        .Display 'display it, if you want direct send , delete this
        .Send    'direct send, if you want manual send, delete this row
    End With
    Range("F" & i) = "SENT"
    
ContinueIt:
    Set OutMail = Nothing
    Set OutApp = Nothing
    Exit Sub
errorKey:
    MsgBox Err.Description
    Resume ContinueIt
End Sub

Thanks for that. Works how I want now. I just tried running the macro with outlook closed though and it ran without error but did not send the email as outlook was closed and it didn't open outlook for me. Ideally I want it to Open outlook if it isn't already and then send it.

How would I finally alter the code so that if I have another sheet within the workbook open, it knows to look at the sheet with the correct data on and run it based on that. The sheet with the correct data is called Data1. When I added the above to the workbook I need it on, it doesn't run when I have other sheets open. However, if I have the sheet open and run it, it obviously runs fine.

One way:

Option Explicit

Sub emailTiger()
Dim dateRow As Integer
With Sheets("Data1")
    dateRow = .Range("D2").End(xlDown).Row
    For i = 2 To dateRow
        If .Range("D" & i).Value < Date And Not .Range("F" & i) = "SENT" Then
            Call emailHim(i)
        End If
        
        If .Range("D" & i).Value = Date And .Range("E" & i).Value < Time And Not .Range("F" & i) = "SENT" Then
            Call emailHim(i)
        End If
    Next i
End With
End Sub

Sub emailHim(i)
    Dim OutApp  As Object
    Dim OutMail  As Object
    
    On Error GoTo errorKey
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    
    On Error Resume Next
    With OutMail
        .Subject = Sheets("Data1").Range("A" & i) & " needs looking at"
        .Body = "Body Text"
        .Recipients.Add ("your email address")
        .Recipients.ResolveAll
        .Display 'display it, if you want direct send , delete this
        .Send    'direct send, if you want manual send, delete this row
    End With
    Sheets("Data1").Range("F" & i) = "SENT"
    
ContinueIt:
    Set OutMail = Nothing
    Set OutApp = Nothing
    Exit Sub
errorKey:
    MsgBox Err.Description
    Resume ContinueIt
End Sub