Run Macros on all except "Summary" and "Reports" worksheets in a workbook

I have a workbook with a macro summarizing the data on the other sheets, but I need to add a "Reports" tab. What can I add/change in the code to exclude this tab?

Here is the code that I have to include all of the worksheets:

Function LastRow(sh As Worksheet)
On Error Resume Next
LastRow = sh.Cells.Find(What:="*", _
After:=sh.Range("A1"), _
Lookat:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByRows, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Row
On Error GoTo 0
End Function

Function LastCol(sh As Worksheet)
On Error Resume Next
LastCol = sh.Cells.Find(What:="*", _
After:=sh.Range("A1"), _
Lookat:=xlPart, _
LookIn:=xlFormulas, _
SearchOrder:=xlByColumns, _
SearchDirection:=xlPrevious, _
MatchCase:=False).Column
On Error GoTo 0
End Function

Sub CopyRangeFromMultiWorksheets()
Dim sh As Worksheet
Dim DestSh As Worksheet
Dim Last As Long
Dim CopyRng As Range

With Application
.ScreenUpdating = False
.EnableEvents = False
End With

' Delete the summary sheet if it exists.
Application.DisplayAlerts = False
On Error Resume Next
ActiveWorkbook.Worksheets("Summary").Delete
On Error GoTo 0
Application.DisplayAlerts = True

' Add a new summary worksheet.
Set DestSh = ActiveWorkbook.Worksheets.Add
DestSh.Name = "Summary"

' Loop through all worksheets and copy the data to the
' summary worksheet.
For Each sh In ActiveWorkbook.Worksheets
If sh.Name <> DestSh.Name Then

' Find the last row with data on the summary worksheet.
Last = LastRow(DestSh)

' Specify the range to place the data.
Set CopyRng = sh.Range("A2:K37")

' Test to see whether there are enough rows in the summary
' worksheet to copy all the data.
If Last + CopyRng.Rows.Count > DestSh.Rows.Count Then
MsgBox "There are not enough rows in the " & _
"summary worksheet to place the data."
GoTo ExitTheSub
End If

' This statement copies values and formats from each
' worksheet.
CopyRng.Copy
With DestSh.Cells(Last + 1, "A")
.PasteSpecial xlPasteValues
.PasteSpecial xlPasteFormats
Application.CutCopyMode = False
End With

' Optional: This statement will copy the sheet
' name in the H column.
DestSh.Cells(Last + 1, "L").Resize(CopyRng.Rows.Count).Value = sh.Name

End If
Next

ExitTheSub:

Application.Goto DestSh.Cells(1)

' AutoFit the column width in the summary sheet.
DestSh.Columns.AutoFit

With Application
.ScreenUpdating = True
.EnableEvents = True
End With
End Sub

Dar,
Welcome to the forum!
Please use code tags with your code. Please read forum's rule.
This code is Ron Deburin's code. It summarise the consolidate sheets in to a sheet called "Summary" Which bit do you want to change or add?

Have not only change the code, but also I used code tags.

Function LastRow(sh As Worksheet)
 On Error Resume Next
 LastRow = sh.Cells.Find(What:="*", _
 After:=sh.Range("A1"), _
 Lookat:=xlPart, _
 LookIn:=xlFormulas, _
 SearchOrder:=xlByRows, _
 SearchDirection:=xlPrevious, _
 MatchCase:=False).Row
 On Error GoTo 0
 End Function

 Function LastCol(sh As Worksheet)
 On Error Resume Next
 LastCol = sh.Cells.Find(What:="*", _
 After:=sh.Range("A1"), _
 Lookat:=xlPart, _
 LookIn:=xlFormulas, _
 SearchOrder:=xlByColumns, _
 SearchDirection:=xlPrevious, _
 MatchCase:=False).Column
 On Error GoTo 0
 End Function

 Sub CopyRangeFromMultiWorksheets()
 Dim sh As Worksheet
 Dim DestSh As Worksheet
 Dim Last As Long
 Dim CopyRng As Range

 With Application
 .ScreenUpdating = False
 .EnableEvents = False
 End With

 ' Delete the summary sheet if it exists.
 Application.DisplayAlerts = False
 On Error Resume Next
 ActiveWorkbook.Worksheets("Summary").Delete
 On Error GoTo 0
 Application.DisplayAlerts = True

 ' Add a new summary worksheet.
 Set DestSh = ActiveWorkbook.Worksheets.Add
 DestSh.Name = "Summary"

 ' Loop through all worksheets and copy the data to the
 ' summary worksheet.
 For Each sh In ActiveWorkbook.Worksheets
 If sh.Name <> DestSh.Name And sh.Name <> "Reports" Then

 ' Find the last row with data on the summary worksheet.
 Last = LastRow(DestSh)

 ' Specify the range to place the data.
 Set CopyRng = sh.Range("A2:K37")

 ' Test to see whether there are enough rows in the summary
 ' worksheet to copy all the data.
 If Last + CopyRng.Rows.Count > DestSh.Rows.Count Then
 MsgBox "There are not enough rows in the " & _
 "summary worksheet to place the data."
 GoTo ExitTheSub
 End If

 ' This statement copies values and formats from each
 ' worksheet.
 CopyRng.Copy
 With DestSh.Cells(Last + 1, "A")
 .PasteSpecial xlPasteValues
 .PasteSpecial xlPasteFormats
 Application.CutCopyMode = False
 End With

 ' Optional: This statement will copy the sheet
 ' name in the H column.
 DestSh.Cells(Last + 1, "L").Resize(CopyRng.Rows.Count).Value = sh.Name

 End If
 Next

ExitTheSub:

 Application.Goto DestSh.Cells(1)

 ' AutoFit the column width in the summary sheet.
 DestSh.Columns.AutoFit

 With Application
 .ScreenUpdating = True
 .EnableEvents = True
 End With
 End Sub