Send email from Excel using Outlook

Sub SendEmail()
 
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object
    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With
 
    Set rng = Nothing
    Set rng = ActiveSheet.UsedRange


    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
 
    On Error Resume Next
    With OutMail
        .To = ActiveSheet.Range("J3").Value
        .CC = ""
        .BCC = ""
        .Subject = "Upcoming Monitoring Deadlines"
        .HTMLBody = RangetoHTML(rng)
        .Send
    End With
    On Error GoTo 0
 
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
 
    Set OutMail = Nothing
    Set OutApp = Nothing

End sub

And this:

Function RangetoHTML(rng As Range)

    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
 
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
 
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         FileName:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
 
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
 
    TempWB.Close savechanges:=False
    Kill TempFile
 
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Copy into a Module.

Originally Posted by clapforthewolfman

' If Date - Worksheets("Monitoring Information").Range("A:A") <= Today() + 7 Then (I would like to add this code but I get a compile error that the sub or function is not defined)

This is referencing all of column A. Its also missing a property. Which Range (cell) are you trying to compare today's day plus 7 (days?) to?

So if any date in column A is within 7 days then the whole work book gets mailed as a reminder?

What about dates in the past?

Lets address this one first. I'll assume dates in the past do not make it to email.

Discard the code I previously posted.

Replace entire module with code below:

Sub HideRows()

    Dim lRow As Long
    Dim i As Long
    Dim iDate As Long
    
    
    Application.ScreenUpdating = True
    
    lRow = Range("A65536").End(xlUp).Row
    
    For i = 4 To lRow
        If IsDate(Range("A" & i).Value) = True Then
            iDate = DateDiff("d", Date, Range("A" & i).Value)
                If iDate < 0 Or iDate > 7 Then
                Cells(i, 1).EntireRow.Hidden = True
                End If
        End If
    Next i
    
    Call SendEmail
            
End Sub

Sub UnhideRows()

    ActiveSheet.Cells.EntireRow.Hidden = False
    
    Application.ScreenUpdating = True

End Sub

Sub SendEmail()

 
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object
    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With
 
    Set rng = Nothing
    Set rng = ActiveSheet.UsedRange.SpecialCells(xlCellTypeVisible)


    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
 
    On Error Resume Next
    With OutMail
        .To = ActiveSheet.Range("J3").Value
        .CC = ""
        .BCC = ""
        .Subject = "Upcoming Monitoring Deadlines"
        .HTMLBody = RangetoHTML(rng)
        .Send
    End With
    On Error GoTo 0
 
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
 
    Call UnhideRows
 
    Set OutMail = Nothing
    Set OutApp = Nothing

End Sub

Function RangetoHTML(rng As Range)

    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
 
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
 
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
 
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.ReadAll
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
 
    TempWB.Close savechanges:=False
    Kill TempFile
 
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

    Dim lRow As Long
    Dim i As Long
    Dim iDate As Long

These declare three variables (names I'll use to store values) and their data type Long (Long is any number between -9,223,372,036,854,775,808 and 9,223,372,036,854,775,807)

The code to send the email copies visible cells this code:

Application.ScreenUpdating = True

makes sure that the screen updating is turned on so that later when we copy cells they ones mark hidden will update to hidden.

lRow = Range("A65536").End(xlUp).Row

Sets the variable we declared in the first step to the last occupied row in column A. If there is data in cells in column a clear down to row 9999 then lRow = 9999.

For i = 4 To lRow

Starts a loop that steps i (another variable declared in step one) from 4 to whatever lRow is set to (our example was 9999 but it changes based on the number of cells occupied.

 If IsDate(Range("A" & i).Value) = True Then

This asks a question if range Ai (remember the value of i varies based on which step of the loop we're in, it has the effect of checking every occupied cell in column) is a date. If this is true then we know it could be one of the cells we want to copy. If it is then we:

iDate = DateDiff("d", Date, Range("A" & i).Value)

set the last variable we defined to a number which is the difference between todays day date, and the date in the stepped range we're looking at.

If this comparison is more than 0 (the date is not in the past) and less than 7 (its within our timeframe therefore we want to keep it in the eamil) we can sort them out with

If iDate < 0 Or iDate > 7 Then

All the rest of the cells we will make invisible so they are not part of our email. We can accomplish this with:

Cells(i, 1).EntireRow.Hidden = True

The rest of this happens in code that you didn't quote -the call sendemail is another Sub with a function that creates an HTML object consisting of the visible cells in the selected range. Lastly we make all cells visible again so they can be edited if need be.

I hope this answers your question, if it does please mark that thread as [SOLVED]