Inner text data from web page

I am having trouble grabbing the inner text (4.00% and 4.25%) from a web pages source code... Any help would be greatly appriciated...

Source Code:

HTML Code: 

VBA Coding:

    Set Pelements = HTMLdoc.getElementsByTagName("P")
    
    Worksheets("WebData").Range("N2:N41").ClearContents
    
    r = 0
    For Each Pelement In Pelements
        If Pelement.Style = "text-align: center;" Then
            Range("N2").Offset(r, 0).Value = Pelement.innerText
            r = r + 1
        End If
    Next

Hi,

What output you are getting currently and if possible let us know the web site address.

Regards
taps

Thanks for the response...

I'm getting no output and the link is..
https://www.fanniemae.com/singlefami...e-modification

Hi Smith3rs,

I think the code you have provide is partial code. However, try this one, here small modification has done...

   Set Pelements = HTMLdoc.getElementsByTagName("P")
    
    Worksheets("WebData").Range("N2:N41").ClearContents
    
    r = 0
    For Each Pelement In Pelements
        If Pelement(r).Style = "text-align: center;" Then
            Range("N2").Offset(r, 0).Value = Pelement(r).innerText
            r = r + 1
        End If
    Next

regards
taps

Hey Taps - Here is the full code.. maybe you can tailor your code to fit in it.. thanks

Sub Extract_FS()

'   Fannie Mae Modification Fixed Interest Rate

'   Runs, but not pulling any data

    Dim URL As String
    Dim IE As InternetExplorer
    Dim HTMLdoc As HTMLDocument
    Dim Pelements As IHTMLElementCollection
    Dim Pelement As HTMLTableCell
    Dim r As Long

'   Goes to and nagivates web page
    
    URL = "https://www.fanniemae.com/singlefamily/fannie-mae-modification"
    
    Set IE = New InternetExplorer
    
    With IE
        .Navigate URL
        .Visible = False
    
        While .Busy Or .ReadyState <> READYSTATE_COMPLETE: DoEvents: Wend
    
        Set HTMLdoc = .Document
    End With
    
'   Allows website to catch up and fully load
    
    Application.Wait Now + TimeValue("00:00:01")
      
'   Searches source code for data
'   Imports to "WebData" sheet

   Set Pelements = HTMLdoc.getElementsByTagName("P")
    
    Worksheets("WebData").Range("N2:N41").ClearContents
    
    r = 0
    For Each Pelement In Pelements
        If Pelement(r).Style = "text-align: center;" Then
            Range("N2").Offset(r, 0).Value = Pelement(r).innerText
            r = r + 1
        End If
    Next
            
End Sub

Another way - this will be much faster:

Sub Extract_FS()
    Dim d
    Dim p As Long
    With CreateObject("winhttp.winhttprequest.5.1")
        .Open "GET", "https://www.fanniemae.com/singlefamily/fannie-mae-modification", False
        .Send
        d = Split(.responseText, "<p style=""text-align: center;"">")
        For p = 1 To UBound(d)
            Worksheets("WebData").Range("N2").Offset(p, 0).Value = Split(d(p), "<")(0)
        Next p
    End With
End Sub

Hey Kyle -

Wow that worked out great! Thank you very much sir.

No problem

Tanks for the feedback

Hi Kyle123,

Your code is fantastic

Hi Smith3rs,

Although Kyle's code is working fine, I am also attaching a code which is modified version of your code.
It is working fine in my computer

Sub Extract_FS_Final()


    Dim URL As String
    Dim HTMLdoc As HTMLDocument
    Dim Pelements As IHTMLElementCollection
    Dim Pelement As HTMLTableCell
    Dim r As Long

    
    URL = "https://www.fanniemae.com/singlefamily/fannie-mae-modification"
    
    Set IE = CreateObject("InternetExplorer.Application")

    IE.Visible = 0
    IE.navigate URL
    state = 0
    
    Do Until state = 4
        DoEvents
        state = IE.readyState
    Loop
    Set HTMLdoc = IE.document
    
    Application.Wait Now + TimeValue("00:00:01")
      
   Set Pelements = HTMLdoc.getElementsByTagName("P")
    
    Worksheets("WebData").Range("A2:A41").ClearContents
    
    r = 0
    For Each Pelement In Pelements
        If Pelement.Style.textAlign = "center" Then
            Range("A2").Offset(r, 0).Value = Pelement.innerText
            r = r + 1
        End If
    Next
          
    MsgBox "Done"
    
End Sub

regards
taps

Thanks

Try to avoid using Internet Explorer unless you really need to, it's slow and nasty. If you are wanting to use the document object model as above, consider:

Sub Extract_FS()

    Dim oDom As Object: Set oDom = CreateObject("htmlFile")
    Dim oNodes As Object
    Dim p
    Dim l As Long
    
    With CreateObject("winhttp.winhttprequest.5.1")
        .Open "GET", "https://www.fanniemae.com/singlefamily/fannie-mae-modification", False
        .Send
        oDom.body.innerHtml = .responseText
    End With
    
    Set oNodes = oDom.getElementsByTagName("p")
    
    For Each p In oNodes
        If p.Style.textAlign = "center" Then
            ActiveSheet.Range("A2").Offset(l, 0).Value = p.innerText
            l = l + 1
        End If
    Next p
    
    
End Sub

Thanks a ton

Regards
taps

You guys are awesome!