Help Importing Multiple Text files into one Excel Sheet

I need help writing a loop to import test files from a folder. The text file are delimited. Any help would be appreciated. This is what I have so far

Sub ReadFilesIntoActiveSheet()
Dim fso As FileSystemObject
Dim folder As folder
Dim file As file
Dim FileText As TextStream
Dim TextLine As String
Dim Items() As String
Dim i As Long
Dim cl As Range

' Get a FileSystem object
Set fso = New FileSystemObject

' get the directory you want
Set folder = fso.GetFolder("C:\Users\wtur\Desktop\June LogFiles\")

' set the starting point to write the data to
Set cl = ActiveSheet.Cells(1, 1)

' Loop thru all files in the folder
For Each file In folder.Files
' Open the file
Set FileText = file.OpenAsTextStream(ForReading)

' Read the file one line at a time
Do While Not FileText.AtEndOfStream
TextLine = FileText.ReadLine

' Parse the line into | delimited pieces
Items = .FieldNames = True
.RowNumbers = False
.FillAdjacentFormulas = False
.PreserveFormatting = True
.RefreshOnFileOpen = False
.RefreshStyle = xlInsertDeleteCells
.SavePassword = False
.SaveData = True
.AdjustColumnWidth = True
.RefreshPeriod = 0
.TextFilePromptOnRefresh = False
.TextFilePlatform = 437
.TextFileStartRow = 1
.TextFileParseType = xlFixedWidth
.TextFileTextQualifier = xlTextQualifierDoubleQuote
.TextFileConsecutiveDelimiter = False
.TextFileTabDelimiter = True
.TextFileSemicolonDelimiter = False
.TextFileCommaDelimiter = False
.TextFileSpaceDelimiter = False
.TextFileColumnDataTypes = Array(1, 1, 1, 1)
.TextFileFixedColumnWidths = Array(3, 19, 3)
.TextFileTrailingMinusNumbers = True
.Refresh BackgroundQuery:=False

' Put data on one row in active sheet
For i = 0 To UBound(Items)
cl.Offset(0, i).Value = Items(i)
Next

' Move to next row
Set cl = cl.Offset(1, 0)
Loop

' Clean up
FileText.Close
Next file

Set FileText = Nothing
Set file = Nothing
Set folder = Nothing
Set fso = Nothing

End Sub

Maybe:

Sub ReadFilesIntoActiveSheet1()
Dim fso, folder, file, FileText, TextLine, Split_line, Count, cl
Set fso = CreateObject("Scripting.filesystemobject")
Set folder = fso.getfolder("E:\Data")
Set cl = ActiveSheet.Cells(1, 1)
For Each file In folder.Files
    If Strings.Right(file, 4) = ".txt" Then
        Set FileText = file.openastextstream()
        Do While Not FileText.AtEndOfStream
            TextLine = FileText.readline
            Split_line = Strings.Split(TextLine, vbTab)
            For Count = 0 To UBound(Split_line)
                cl.Offset(0, Count).Value = Split_line(Count)
            Next
            Set cl = cl.Offset(1, 0)
        Loop
    End If
    FileText.close
Next File
Set FileText = Nothing
Set file = Nothing
Set folder = Nothing
Set fso = Nothing
End Sub

First of all thanks for the reply. This loaded everything. But its space delimited and I didn't separate everything in to its own column.

Can you upload an example text file and desired result in a spreadsheet? When replying click go advanced and the attachments

HowIWantTheDataToLookLike.xlsxSCADAlarm Logfile [2013-06-24].txtSCADAlarm Logfile [2013-06-25].txt

Maybe:

Sub ReadFilesIntoActiveSheet1()
Dim fso, folder, file, FileText, TextLine, Split_line, Count, cl
Set fso = CreateObject("Scripting.filesystemobject")
Set folder = fso.getfolder("E:\Data")
Set cl = ActiveSheet.Cells(1, 1)
For Each file In folder.Files
    If Strings.Right(file, 4) = ".txt" Then
        Set FileText = file.openastextstream()
        Do While Not FileText.AtEndOfStream
            TextLine = FileText.readline
            Split_line = Strings.Split(TextLine, " ")
            cl.Offset(0, 0).Value = Split_line(0)
            If Split_line(3) = "" Then
                cl.Offset(0, 1).Value = Split_line(2) & " " & Split_line(4)
                cl.Offset(0, 2).Value = Split_line(5)
                cl.Offset(0, 3).Value = Split_line(6)
                For Count = 7 To UBound(Split_line)
                    cl.Offset(0, 3).Value = cl.Offset(0, 3).Value & " " & Split_line(Count)
                Next
            Else
                cl.Offset(0, 1).Value = Split_line(2) & " " & Split_line(3)
                cl.Offset(0, 2).Value = Split_line(4)
                cl.Offset(0, 3).Value = Split_line(5)
                For Count = 6 To UBound(Split_line)
                    cl.Offset(0, 3).Value = cl.Offset(0, 3).Value & " " & Split_line(Count)
                Next
            End If
            Set cl = cl.Offset(1, 0)
        Loop
    FileText.Close
    End If
Next file
Set FileText = Nothing
Set file = Nothing
Set folder = Nothing
Set fso = Nothing
End Sub

Well it started to work then I received an error. Inserted page shots of the errors. Thanks for the help
error message.JPGerror message2.JPG

Hard to know what the problem is from that. Do you have text files in different formats? What file was it trying to import? What was the value of split_line(0) at that point?

The most likely issue is that the line was empty or something so split line is set to empty and split_line(0) doesn't exist. Try something like:

Sub ReadFilesIntoActiveSheet1()
Dim fso, folder, file, FileText, TextLine, Split_line, Count, cl
Set fso = CreateObject("Scripting.filesystemobject")
Set folder = fso.getfolder("E:\Data")
Set cl = ActiveSheet.Cells(1, 1)
For Each file In folder.Files
    If Strings.Right(file, 4) = ".txt" Then
        Set FileText = file.openastextstream()
        Do While Not FileText.AtEndOfStream
            TextLine = FileText.readline
            if not TextLine = "" then
            Split_line = Strings.Split(TextLine, " ")
            cl.Offset(0, 0).Value = Split_line(0)
            If Split_line(3) = "" Then
                cl.Offset(0, 1).Value = Split_line(2) & " " & Split_line(4)
                cl.Offset(0, 2).Value = Split_line(5)
                cl.Offset(0, 3).Value = Split_line(6)
                For Count = 7 To UBound(Split_line)
                    cl.Offset(0, 3).Value = cl.Offset(0, 3).Value & " " & Split_line(Count)
                Next
            Else
                cl.Offset(0, 1).Value = Split_line(2) & " " & Split_line(3)
                cl.Offset(0, 2).Value = Split_line(4)
                cl.Offset(0, 3).Value = Split_line(5)
                For Count = 6 To UBound(Split_line)
                    cl.Offset(0, 3).Value = cl.Offset(0, 3).Value & " " & Split_line(Count)
                Next
            End If
            Set cl = cl.Offset(1, 0)
            End If
        Loop
    FileText.Close
    End If
Next file
Set FileText = Nothing
Set file = Nothing
Set folder = Nothing
Set fso = Nothing
End Sub

That worked Great. There was a space in my data that I never noticed. I apriciate all the help. Have a great day.