Remove duplicates and sort data for populating a combobox using VBA

Hi all

I am trying to populate a combobox on a userform with data list from a sheet (strSheetName). I want to first remove duplicates and blanks from the list, sort the data in decending order and then populate a combobox.

I have the code to remove duplicates and populate the combobox as shown below, but I don't know how to amend it to remove blanks and to sort it. Can anyone help advise?

Private Sub Populate_cboSupplier()
    Dim Lr As Long, cell As Range
    'Populate Combobox1 with unique names from Sheets(1) column D
    With Sheets(strSheetName)
        Lr = .Range("H" & Rows.Count).End(xlUp).Row
        .Range("H2:H" & Lr).AdvancedFilter Action:=xlFilterInPlace, Unique:=True
        cboSuppliers.Clear
        For Each cell In .Range("H3:H" & Lr).SpecialCells(xlCellTypeVisible)
            cboSuppliers.AddItem cell.Value
        Next cell
        On Error Resume Next
        .ShowAllData
        On Error GoTo 0
    End With
End Sub

Any suggestions?

Other method

Private Sub Populate_cboSupplier()
    Dim a, e
    cboSuppliers.Clear
    With Sheets(strSheetName)
        a = .Range("H2", .Range("H" & Rows.Count).End(xlUp)).Value
    End With
    With CreateObject("System.Collections.ArrayList")
        For Each e In a
            If (e <> "") * (Not .Contains(CStr(e))) Then
                .Add CStr(e)
            End If
        Next
        .Sort: .Reverse
        cboSuppliers.List = .ToArray
    End With
End Sub

Jindon

You have come to my rescue again! Works much better now, but it's giving list from z to a. How can I make it a to z?

Thanks very much

A-Z...
Remove

: .Reverse

Sorted! (pardon the pun!)

Thanks, friend