if cell = x then copy paste info in K1 or k2, etc..If cell = y, then copy info in D1,d2, e

Hi,

adapt the name of the target sheet. The values will be copied into column A:

Sub test()
    Dim xlWs As Worksheet
    Dim i As Long, lngNextRow As Long
    
    On Error GoTo test_ErrorHandler
    Application.ScreenUpdating = False
    
    Set xlWs = Worksheets("Another Sheet")  'adapt sheetname for target sheet
    With xlWs
        lngNextRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1   'will be pasted into next free row in target sheet
    End With
    With ActiveSheet
        For i = 2 To .Cells(.Rows.Count, 4).End(xlUp).Row
            Select Case .Cells(i, 4).Value
                Case "Matched"
                    xlWs.Cells(lngNextRow, 1).Value = .Cells(i, 11).Value   'from K
                    lngNextRow = lngNextRow + 1
                Case "No Match"
                    xlWs.Cells(lngNextRow, 1).Value = .Cells(i, 8).Value    'from G
                    lngNextRow = lngNextRow + 1
                Case Else
                    
            End Select
        Next i
    End With

test_Proc_Exit:
    Application.ScreenUpdating = True
    Exit Sub
test_ErrorHandler:
    MsgBox "Error: " & Err.Number & " (" & Err.Description & ") in Sub 'test' of Module 'Module1'.", vbOKOnly + vbCritical, "Error"
    Resume test_Proc_Exit
End Sub

Hi,

I wrote it according to your instructions in post #1, could you please upload a sample workbook?

Hi

I assume the headings in the Result sheet correspond to the values in column B of the source sheet? if this is true try:

Option Explicit

Sub test()
    Dim xlWs As Worksheet
    Dim xlRng As Range
    Dim i As Long, lngNextRow As Long
    
    On Error GoTo test_ErrorHandler
    Application.ScreenUpdating = False
    
    Set xlWs = Worksheets("Result")  'adapt sheetname for target sheet
    With ActiveSheet
        For i = 2 To .Cells(.Rows.Count, 4).End(xlUp).Row
            Select Case .Cells(i, 4).Value
                Case "MATCH"    'from K
                    If .Cells(i, 11).Value <> 0 Then
                        Set xlRng = xlWs.Rows(1).Find(WHat:=.Cells(i, 2).Value, LookIn:=xlValues, lookat:=xlWhole)
                        If Not xlRng Is Nothing Then
                            xlWs.Cells(xlWs.Cells(xlWs.Rows.Count, xlRng.Column).End(xlUp).Row + 1, xlRng.Column).Value = .Cells(i, 11).Value
                        Else
                            Err.Raise vbObjectError + 512
                        End If
                    End If
                Case "NO MATCH"     'from G
                    If .Cells(i, 8).Value <> 0 Then
                        Set xlRng = xlWs.Rows(1).Find(WHat:=.Cells(i, 2).Value, LookIn:=xlValues, lookat:=xlWhole)
                        If Not xlRng Is Nothing Then
                            xlWs.Cells(xlWs.Cells(xlWs.Rows.Count, xlRng.Column).End(xlUp).Row + 1, xlRng.Column).Value = .Cells(i, 8).Value
                        Else
                            Err.Raise vbObjectError + 512
                        End If
                    End If
                Case Else
                    
            End Select
        Next i
    End With

test_Proc_Exit:
    Application.ScreenUpdating = True
    Exit Sub
test_ErrorHandler:
    MsgBox "Error: " & Err.Number & " (" & Err.Description & ") in Sub 'test' of Module 'Module1'.", vbOKOnly + vbCritical, "Error"
    Resume test_Proc_Exit
End Sub

Hi,

1. Does the error occur in the sample file from post #5?
2. What is the error message?
3. Was there anything copied?