password for command button

Try something like....
In the CommandButton code

Private Sub CommandButton1_Click()
UNsht
End Sub

In a standard module

Sub UNsht()
    Dim pw As String
    pw = InputBox("Enter password", "Unprotect sheets")
    On Error GoTo pwerr
    ActiveSheet.Unprotect Password:=pw
    Exit Sub
pwerr:
    If MsgBox("Incorrect password", vbRetryCancel, "Error") = vbRetry Then
        UNsht
    End If
End Sub

Sorry my fault for not reading the question properly. Replace all the code with...

In the CommandButton code

Private Sub CommandButton2_Click()
UNsht
End Sub

In a standard module

Sub UNsht()
    Dim pw As String, sht As Worksheet
    pw = InputBox("Enter password", "Unprotect sheets")
    On Error GoTo pwerr
    For Each sht In ActiveWorkbook.Worksheets
    sht.Unprotect Password:=pw
    Next
    Exit Sub
pwerr:
    If MsgBox("Incorrect password", vbRetryCancel, "Error") = vbRetry Then
        UNsht
    End If
End Sub

EDIT: or actually you can just put it all in the command button code

Private Sub CommandButton2_Click()
    Dim pw As String, sht As Worksheet
    pw = InputBox("Enter password", "Unprotect sheets")
    On Error GoTo pwerr
    For Each sht In ActiveWorkbook.Worksheets
    sht.Unprotect Password:=pw
    Next
    Exit Sub
pwerr:
    If MsgBox("Incorrect password", vbRetryCancel, "Error") = vbRetry Then
        UNsht
    End If
End Sub

Obviously too much beer today

Private Sub CommandButton2_Click()
    Dim pw As String, sht As Worksheet
    pw = InputBox("Enter password", "Unprotect sheets")
    On Error GoTo pwerr
    For Each sht In ActiveWorkbook.Worksheets
    sht.Unprotect Password:=pw
    Next
    Exit Sub
pwerr:
    If MsgBox("Incorrect password", vbRetryCancel, "Error") = vbRetry Then
        CommandButton2_Click
    End If
End Sub

Perhaps

Sub ProtectSheets()
    Dim LastPW As String, NewPW As String
    Dim oneSheet As Worksheet
    LastPW = getStoredWord
    NewPW = ChoosePassword(LastPW)
    If NewPW <> "False" Then
        For Each oneSheet In ThisWorkbook.Sheets
            oneSheet.Protect Password:=NewPW, contents:=True, DrawingObjects:=True, Scenarios:=True
        Next oneSheet
        StoreWord vbNullString
    End If
End Sub

Sub UnProtectSheets()
    Dim oneSheet As Worksheet
    Dim uiPW As String
    If Sheet1.ProtectContents Then
        uiPW = ChoosePassword(oneShot:=True)
        If uiPW <> "False" Then
            On Error Resume Next
            For Each oneSheet In ThisWorkbook.Sheets
                oneSheet.Unprotect Password:=uiPW
            Next oneSheet
            On Error GoTo 0
            If Sheet1.ProtectContents Then
                MsgBox "Password mismatch"
            Else
                StoreWord uiPW
            End If
        End If
    End If
End Sub

Sub StoreWord(ByRef wordToStore As String)
    Dim LastWord As String
    With ThisWorkbook
        On Error Resume Next
        .CustomDocumentProperties("LastPassword").Delete
        .CustomDocumentProperties.Add Name:="LastPassword", LinkToContent:=False, Type:=msoPropertyTypeString, _
            Value:=wordToStore
    End With
End Sub

Function getStoredWord() As String
    With ThisWorkbook
    On Error Resume Next
        With .CustomDocumentProperties("LastPassword")
            getStoredWord = .Value
        End With
    On Error GoTo 0
    End With
End Function

Function ChoosePassword(Optional defaultPW As String, Optional oneShot As Boolean) As String
    Dim uiPW As String
    uiPW = Application.InputBox("Enter your password", Default:=defaultPW, Type:=2)
    If uiPW <> "False" And uiPW <> defaultPW Then
        If Not oneShot Then
        If uiPW <> Application.InputBox("Re-enter the password", Type:=2) Then
            MsgBox "Passwords do not match"
            uiPW = "False"
        End If
        End If
    End If
    ChoosePassword = uiPW
End Function