Define range and then unmerge/edit range

Hi all,

I'm not sure how to write the syntax for a little bit of code i am trying to complete.

Im not sure how to name a range that is ("A7:N"&lastrow),
and then go through that range and:
-unmerge all cells within the range
-Look in column C and if it is blank then clear the column N value in the same row.
-look in column A and if it is blank delete the entire row.

I already have the variable lastrow defined so no need to define it in your replies

Thanks for your help I've been trying to get this part for a while.

Range("A7:N" & Lastrow).Cells.UnMerge

and

Dim Cell as Range
For Each Cell In Range("A7:A" & Lastrow)
   ' do whatever
   If Cell.Offset(0,2).Value = "" Then
           Cell.Offset(0, 13).Value = ""
   End If
Next 'Cell

Regards, TMS

OK, try this, all the requirements in one subroutine.

Sub sDoStuff()

Dim LastRow As Long
Dim Cell As Range
Dim rRngToDelete As Range

LastRow = Cells.SpecialCells(xlCellTypeLastCell).Row

' unmerge cells in range
Range("A7:N" & LastRow).Cells.UnMerge

For Each Cell In Range("A7:A" & LastRow)
    ' build range to delete
    If Cell.Value = "" Then
        If rRngToDelete Is Nothing Then
            Set rRngToDelete = Cell
        Else
            Set rRngToDelete = Union(rRngToDelete, Cell)
        End If
    End If
    
    ' clear column N if column C is blank
    If Cell.Offset(0, 2).Value = "" Then
        Cell.Offset(0, 13).Value = ""
    End If
Next 'Cell

' delete cells if appropriate
If Not rRngToDelete Is Nothing Then
    rRngToDelete.EntireRow.Delete
End If

End Sub

Regards, TMS

You're welcome. Thanks for the rep.