Need to copy values from all files in folder from specific worksheet

Trying to create a macro that will copy data from a specific range (A3:H8) in a specific sheet(Assay Chart) from closed files in the same folder. The files are created off a template where just the data in certain cells change. The data needs to be pasted as values as I am planning on graphing the data on one graph once copied over to my new sheet. If more info is needed let me know. I would like to have the data stacked. I have tried to build one on my own but I am new to creating code and I have not had much success.

I found this code that is close to what I need after a couple modifications. But I need it to add the values vertically and not horizontal with the file name preferably in column next to the data while keeping source formatting. Also, don't need to create new workbook and sheet, need to keep in current one. Any ideas?

Option Explicit
Sub MergeHorizontally()
    Dim MyPath As String, FilesInPath As String
    Dim MyFiles() As String
    Dim SourceCcount As Long, FNum As Long
    Dim mybook As Workbook, BaseWks As Worksheet
    Dim sourceRange As Range, destrange As Range
    Dim Cnum As Long, CalcMode As Long

    ' Change this to the path\folder location of the files.
    MyPath = "C:\Trending Data\"

    ' Add a slash at the end of path if needed.
    If Right(MyPath, 1) <> "\" Then
        MyPath = MyPath & "\"
    End If

    ' If there are no Excel files in the folder, exit.
    FilesInPath = Dir(MyPath & "*.xls*")
    If FilesInPath = "" Then
        MsgBox "No files found"
        Exit Sub
    End If

    ' Fill in the myFiles array with the list of Excel files in
    ' the search folder.
    FNum = 0
    Do While FilesInPath <> ""
        FNum = FNum + 1
        ReDim Preserve MyFiles(1 To FNum)
        MyFiles(FNum) = FilesInPath
        FilesInPath = Dir()
    Loop

    ' Change the application properties.
    With Application
        CalcMode = .Calculation
        .Calculation = xlCalculationManual
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    ' Add a new workbook with one sheet.
    Set BaseWks = Workbooks.Add(xlWBATWorksheet).Worksheets(1)
    Cnum = 1

    ' Loop through all of the files in the myFiles array.
    If FNum > 0 Then
        For FNum = LBound(MyFiles) To UBound(MyFiles)
            Set mybook = Nothing
            On Error Resume Next
            Set mybook = Workbooks.Open(MyPath & MyFiles(FNum))
            On Error GoTo 0

            If Not mybook Is Nothing Then

                On Error Resume Next
                Set sourceRange = mybook.Worksheets(3).Range("b3:h8")

                If Err.Number > 0 Then
                    Err.Clear
                    Set sourceRange = Nothing
                Else
                    ' If the source range uses all of the rows
                    ' then skip this file.
                    If sourceRange.Rows.Count >= BaseWks.Rows.Count Then
                        Set sourceRange = Nothing
                    End If
                End If
                On Error GoTo 0

                If Not sourceRange Is Nothing Then

                    SourceCcount = sourceRange.Columns.Count

                    If Cnum + SourceCcount >= BaseWks.Columns.Count Then
                        MsgBox "There are not enough columns in the sheet."
                        BaseWks.Columns.AutoFit
                        mybook.Close savechanges:=False
                        GoTo ExitTheSub
                    Else

                        ' Copy the file name in the first row.
                        With sourceRange
                            BaseWks.Cells(1, Cnum). _
                                    Resize(, .Columns.Count).Value = MyFiles(FNum)
                        End With

                        ' Set the destination range.
                        Set destrange = BaseWks.Cells(3, Cnum)

                        ' Copy the values from the source range
                        ' to the destination range.
                        With sourceRange
                            Set destrange = destrange. _
                                            Resize(.Rows.Count, .Columns.Count)
                        End With
                        destrange.Value = sourceRange.Value

                        Cnum = Cnum + SourceCcount
                    End If
                End If
                mybook.Close savechanges:=False
            End If

        Next FNum
        BaseWks.Columns.AutoFit
    End If

ExitTheSub:
    'Restore ScreenUpdating, Calculation and EnableEvents
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .Calculation = CalcMode
    End With

End Sub

Forgot I need to open all files in sub folders as well. I have looked for ideas but not much luck.

'Initialise the following varibales to the first *.xls file in the designated folder
     FolderPath = "C:\Documents and Settings\Trending Data\" 'Change to your own path
     If Right(FolderPath, 1) <> "\" Then ' Add a slash at the end of the path if needed.
        FolderPath = FolderPath & "\"
     End If
     Filename = Dir(FolderPath & "*.xls") 'Excel 2003 file types to import
   
    Do Until Filename = ""
    
        Set sourceBook = Workbooks.Open(FolderPath & Filename)
        
         With sourceBook.Worksheets(3)
                  LR = .Cells.Find("*", , , , xlByRows, xlPrevious).Row
                  NR = shtMy.Cells.Find("*", , , , xlByRows, xlPrevious).Row + 1
                  .Range("A3:H4").Copy
                   shtMy.Range("B" & NR).PasteSpecial xlValues
                   shtMy.Range("A" & NR).Resize(LR - 5) = Filename
                    Application.DisplayAlerts = False
                    sourceBook.Close SaveChanges:=False
                    Application.DisplayAlerts = True
                 
        End With
      
        Filename = Dir()
    
    Loop
   
    With Application
        .ScreenUpdating = True
        .EnableEvents = True
        .AskToUpdateLinks = True
        .Calculation = CalcMode
    End With