Import text file into excel and split data in specific sheets

Hello,
I attached my .txt data file named "data". I also attach the excel file, to help you to understand what i really need.
I need a VBA solution for import the informations in excel.
The challenge is to split this data into multiple sheets, by "Node Name".

for example:
in sheet 1, will be imported data from node name 17GHEB, the sheet name will become 17GHEB.
so on

best regards, i hope somebody can help me

Sub Import_Node_Text()
Dim fs, fil, cur_line, s_name, row_count
Set fs = CreateObject("Scripting.filesystemobject")
Set fil = fs.opentextfile("E:\data.txt")
Do
    On Error GoTo end_file
    row_count = 1
    Sheets.Add After:=Sheets(Sheets.Count)
    Range("A" & row_count) = cur_line
    row_count = 2
    Do Until Strings.Left(cur_line, 9) = "Node Name"
        cur_line = fil.readline
        Range("A" & row_count) = cur_line
        row_count = row_count + 1
    Loop
    s_name = Strings.Left(cur_line, InStr(1, cur_line, "Board ID") - 10)
    s_name = Replace(s_name, "Node Name    : ", "")
    ActiveSheet.Name = Replace(s_name, " ", "")
    Do
        cur_line = fil.readline
        If Strings.Left(cur_line, 5) = "Daily" Then Exit Do
        Range("A" & row_count + 1) = cur_line
        row_count = row_count + 1
    Loop
Loop
Exit Sub
end_file:
End Sub

Thanks yudlugar! that code works really fine. but that informations are copied into one column.
I need to get that data in separate columns. In fact, i need to get only day, volume and energy. can be done?
Anyway, i appreciate your effort, you are really good!
Best regards,
Ionut

Try this

Sub test()
    Dim fn As String, x, n As Long, t As Long, e
    fn = ThisWorkbook.Path & "\data.txt"  '<- file path
    x = Split(CreateObject("Scripting.FileSystemObject").OpenTextFile(fn).ReadAll, vbCrLf)
    With CreateObject("VBScript.RegExp")
        .Global = True
        For Each e In x
            .Pattern = "^Node Name *: *(\S+)"
            If .test(e) Then
                t = t + 1: n = 1
                If t > Sheets.Count Then
                    Sheets.Add(after:=Sheets(Sheets.Count)).Name = _
                    .Execute(e)(0).submatches(0)
                Else
                    Sheets(t).Name = .Execute(e)(0).submatches(0)
                    Sheets(t).Cells.Clear
                End If
                Sheets(t).Cells(n, 1).Resize(, 4).Value = _
                [{"day","Flow hrs.","Energy kWh","Volume m3"}]
            End If
            If n > 0 Then
                .Pattern = "^ *(\d+) *(\d+\.\d{2}).* +(\d+\.\d{2}) *(\d+\.\d{2}) *$"
                If .test(e) Then
                    n = n + 1
                    Sheets(t).Cells(n, 1).Resize(, 4).Value = _
                    Split(.Replace(e, "$1-$2-$3-$4"), "-")
                End If
            End If
        Next
    End With
End Sub

I came up with this:

Option Explicit

Sub Import_Node_Text()
Dim fs, fil, cur_line, split_line, s_name, row_count
Set fs = CreateObject("Scripting.filesystemobject")
Set fil = fs.opentextfile("E:\data.txt")
Do
    On Error GoTo end_file
    row_count = 1
    Sheets.Add After:=Sheets(Sheets.Count)
    Range("A" & row_count) = cur_line
    row_count = 2
    Do Until Strings.Left(cur_line, 9) = "Node Name"
        cur_line = fil.readline
        Range("A" & row_count) = cur_line
        row_count = row_count + 1
    Loop
    s_name = Strings.Left(cur_line, InStr(1, cur_line, "Board ID") - 10)
    s_name = Replace(s_name, "Node Name    : ", "")
    ActiveSheet.Name = Replace(s_name, " ", "")
    Do
        cur_line = fil.readline
        If Strings.InStr(1, cur_line, "Flags") Then
            Range("A" & row_count) = "Day"
            Range("B" & row_count) = "Energy"
            Range("C" & row_count) = "Volume"
            row_count = row_count + 1
            cur_line = fil.readline
            cur_line = fil.readline
            Do
                cur_line = fil.readline
                If Strings.Left(cur_line, 1) = "-" Then Exit Do
                Range("A" & row_count) = Replace(Strings.Left(cur_line, 9), " ", "")
                Range("C" & row_count) = Replace(Strings.Right(cur_line, 15), " ", "")
                Range("B" & row_count) = Replace(Replace(Strings.Right(cur_line, 35), " ", ""), Range("C" & row_count), "")
                row_count = row_count + 1
            Loop
        End If
        If Strings.Left(cur_line, 5) = "Daily" Then Exit Do
        Range("A" & row_count + 1) = cur_line
        row_count = row_count + 1
    Loop
Loop
Exit Sub
end_file:
End Sub

Did you change the filepath?

Place both Excel and text file in the same folder and try again.

It is working here.

a stupid question: if i want to import other column (for example: "pressure" from that .txt file, what should i change into the jindon's code?
i looked at the code 1 hour today and i still feel stupid...
thanks again, you are doing a great job!

thanks man! you rulllzzzzzzz!

Can you just add one space after 3 rd asterisk?

            If n > 0 Then
                .Pattern = "^ *(\d+) *(\d+\.\d{2}).\D+ +(\d+\.\d{2}).* (\d+\.\d{2}) *(\d+\.\d{2}) *$"

Thx, u r big in japan!
have a nice day!

jindon, could you explain the logic of this code?
i understand it about 90%, but something it's not very clear to me. for instance, i try to extend that code for 6 columns:

Sheets(t).Cells(n, 1).Resize(, 6).Value = _
[{"day","Flow hrs.","presure","diff","Energy kWh","Volume m3"}]
End If
If n > 0 Then
.Pattern = "^ *(\d+) *(\d+\.\d{2}).\D+ *(\d+\.\d{2})*(\d+\.\d{2}).\D+ +(\d+\.\d{2}).* (\d+\.\d{2}) *(\d+\.\d{2})*(\d+\.\d{2}) *$"

but, it appear a blank on "pressure" column. what i did wrong?
it seems that i am not smart enough...

            If n > 0 Then
                .Pattern = "^ *(\d+) *(\d+\.\d{2}).\D+ +(\d+\.\d{2}) *(\d+\.\d{2}).* (\d+\.\d{2}) *(\d+\.\d{2}) *$"
                If .test(e) Then
                    n = n + 1
                    Sheets(t).Cells(n, 1).Resize(, 6).Value = _
                    Split(.Replace(e, "$1-$2-$3-$4-$5-$6"), "-")
                End If
            End If

finally i get it!! i understand the meaning of code! you are great man, i really apreciate your work! thanks very much again, best regards!