How to copy value of selected cell to windows clipboard?

[1tane1]

Sub basvuruac()
    With New DataObject
        SetText ActiveCell.Value
        PutInClipboard
    End With
    On Error GoTo 1
    Call Shell(Environ$("COMSPEC") & " /c ""C:\Documents and Settings\burak\Desktop\# Başvurular\Bitmeyenler\islembekleyen.bat""", vbNormalFocus)
    Exit Sub
1:           MsgBox Err.Description
End Sub

I have the code above. I need to copy active cell value for my other uses. Someone said the answer above in bold but then I got error. Could you give me a hint please?

Selection.Copy
Application.CutCopyMode = False

doesn't work.

Selection.Copy

works but I don't want this cell remain as selected.

[patel45]

Sub basvuruac()
ActiveCell.Copy
Call Shell(Environ$("COMSPEC") & " /c ""C:\Documents and Settings\burak.kurtulan\Desktop\# Başvurular\Bitmeyenler\islembekleyen.bat""", vbNormalFocus)
Application.CutCopyMode = False
End Sub

if problems explain better your goal

[JosephP]

if you use the early bound dataobject you must set a reference to the microsoft forms 2 object library

[1tane1]

Application.CutCopyMode = False

doesn't work. Clipboard becomes empty.

Could you elaborate more on object library? Because I'm vba illiterate. I just combine vba parts from internet for my own use, but I don't type them, if they are really complicated.

[JosephP]

in the vb editor select tools-references on the menu and then find and check the "Microsoft Forms 2.0 Object Library"

[buran]

As JosephP said, you need to set up reference to Microsoft Forms 2.0 Object Library in order to make your original code to work.
To do this, in VBE go to Tools->References find Microsoft Forms 2.0 Object Library and tick the checkbox

[1tane1]

I added Microsoft Forms 2.0 Object Library. Then I got an error. Debugger highlighted SetText, saying:
Compile error:
Sub or Function not defined

so, now how to define SetText?

[buran]

Sub basvuruac()
Dim objMyData As DataObject

Set objMyData = New DataObject
    With objMyData
        .SetText ActiveCell.Value
        .PutInClipboard
    End With
    On Error GoTo 1
    Call Shell(Environ$("COMSPEC") & " /c ""C:\Documents and Settings\burak\Desktop\# Bas,vurular\Bitmeyenler\islembekleyen.bat""", vbNormalFocus)
    Exit Sub
1:           MsgBox Err.Description
End Sub

Note the dots in front of SetText and PutInClipboard

[1tane1]

Sub basvuruac()
Dim objMyData As DataObject

Set objMyData = New DataObject
    With objMyData
        .SetText ActiveCell.Value
        .PutInClipboard
    End With
    On Error GoTo 1
    Call Shell(Environ$("COMSPEC") & " /c ""C:\Documents and Settings\burak\Desktop\# Bas,vurular\Bitmeyenler\islembekleyen.bat""", vbNormalFocus)
    Exit Sub
1:           MsgBox Err.Description
End Sub

Note the dots in front of SetText and PutInClipboard

That worked perfectly. Thank you very much.

I became happy when my codes work :D