Macro to Export Word Tables to Excel

I have a Word document that has several tables which I would like to pull into Excel (each table on a separate sheet). I have been copying/pasting the tables, but was wondering if there is a macro that can pull them in for me.

I found the following macro online, but when I add it as a module in Excel, I get a run-time error at the

wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", , _
"Browse for file containing table to be imported")

line.

Does anyone know why?

I am using Office 2010, and am on a MAC. I tried this on a PC as well and still got an error.

Sub ImportWordTable()
Dim wdDoc As Object
Dim wdFileName As Variant
Dim TableNo As Integer 'table number in Word
Dim iRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel

wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", , _
"Browse for file containing table to be imported")

If wdFileName = False Then Exit Sub '(user cancelled import file browser)

Set wdDoc = GetObject(wdFileName) 'open Word file

With wdDoc
TableNo = wdDoc.tables.Count
If TableNo = 0 Then
MsgBox "This document contains no tables", _
vbExclamation, "Import Word Table"
ElseIf TableNo > 1 Then
TableNo = InputBox("This Word document contains " & TableNo & " tables." & vbCrLf & _
"Enter table number of table to import", "Import Word Table", "1")
End If
With .tables(TableNo)
'copy cell contents from Word table cells to Excel cells
For iRow = 1 To .Rows.Count
For iCol = 1 To .Columns.Count
Cells(iRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
Next iCol
Next iRow
End With
End With

Set wdDoc = Nothing

End Sub

Yes, the file I want to import is a .doc file.
I found a forum that said sometimes you have to replace the quotes as they don't come across correctly when copied. That didn't fix it, but it did highlight that the underscore in this line was "invalid character."

wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", ,  _ "Browse for file containing table to be imported")

I tried deleting the underscore and also tried adding a file name

wdFileName = Application.GetOpenFilename("Word files (*.doc),*.doc", "Test.doc", "Browse for file containing table to be imported")

but in both cases I get a "type mismatch" error on the following line:

If wdFileName = False Then Exit Sub '(user cancelled import file browser)

I know it's something I'm not doing correctly, but I'm not sure what it is. . .

Found an answer: on a MAC, the line has to read:

wdFileName = Application.GetOpenFilename( )

There were multiple other errors in the code I had copied, but I found the correct text to loop through all tables in Word and import them to excel on this thread:

HTML Code: 

Sub ImportWordTable3()
'Import all tables to a single sheet
Dim wdDoc As Object
Dim wdFileName As Variant
Dim TableNo As Integer 'table number in Word
Dim iRow As Long 'row index in Word
Dim jRow As Long 'row index in Excel
Dim iCol As Integer 'column index in Excel

wdFileName = Application.GetOpenFilename()

If wdFileName = False Then Exit Sub '(user cancelled import file browser)

Set wdDoc = GetObject(wdFileName) 'open Word file

With wdDoc
    If wdDoc.tables.Count = 0 Then
        MsgBox "This document contains no tables", _
            vbExclamation, "Import Word Table"
    Else
        jRow = 0
        Sheets.Add after:=Sheets(Worksheets.Count)
        For TableNo = 1 To wdDoc.tables.Count
            With .tables(TableNo)
'copy cell contents from Word table cells to Excel cells
                For iRow = 1 To .Rows.Count
                    jRow = jRow + 1
                    For iCol = 1 To .Columns.Count
                        On Error Resume Next
                        ActiveSheet.Cells(jRow, iCol) = WorksheetFunction.Clean(.cell(iRow, iCol).Range.Text)
                        On Error GoTo 0
                    Next iCol
                Next iRow
            End With
            jRow = jRow + 1
        Next TableNo
    End If
End With
Set wdDoc = Nothing
End Sub

Thanks a million, Western Gal. I had searched for days and worked sooo many hours to try to solve this problem. With your code plus a couple of tiny twiddles to it to import data from just one single-line table, it ran perfectly on my Windows PC.