User Form with option buttons

You could put the code in the Click events of the buttons.

Or have a separate sub that runs the existing code and call that from the Click event of each option button.

Can you attach a workbook with an example form with option buttons?

Try this.

Option Explicit

Private Sub OptionBMW_Click()
    GetVehicle
End Sub

Private Sub OptionMercedes_Click()
    GetVehicle
End Sub

Private Sub OptionVolvo_Click()
    GetVehicle
End Sub

Private Sub OptionCost_Click()
    GetMetric
End Sub

Private Sub OptionUnits_Click()
    GetMetric
End Sub

Private Sub UserForm_Initialize()
    Me.ActivityList.ListIndex = 1
    Me.MonthList.ListIndex = 2
End Sub
Private Sub ActivityList_Click()
    Range("ActivityChosen").Value = Me.ActivityList.Value
End Sub
Private Sub MonthList_Click()
    Range("MonthChosen").Value = Me.MonthList.Value
End Sub
Private Sub CancelButton_Click()
    Unload UserForm1
End Sub

Sub GetVehicle()
Dim strVehicle As String

    Select Case True
        Case OptionBMW
            strVehicle = "BMW"
        Case OptionVolvo
            strVehicle = "Volvo"
        Case OptionMercedes
            strVehicle = "Mercedes"
    End Select

    Range("VehicleChosen").Value = strVehicle
End Sub

Sub GetMetric()
Dim strMetric As String

    Select Case True
        Case OptionUnits
            strMetric = "Unit"
        Case OptionCost
            strMetric = "Cost"
    End Select

    Range("Metric").Value = strMetric

End Sub