Graphing dynamic range with vba

Hi!
I am trying to graph a dynamic range using VBA, but don't know how to get all of the data I need on to one chart.
I came very close, please see the attached sheet. I've gotten thus far thanks to John Peltier's blog.

The data on the sheet looks like this:
.......................Apr2 Apr 14 Apr 21
Physical percentage 90 92 93
Economic percentage 91 93 94

I can get the numbers onto the graph, but I cant get the dates to be displayed on the x-axis of the graph through VBA.
If I take the boxes around the data and drag them over the dates, they appear on the graph.

What can I do to make the dates appear on the x-axis of the chart?
Its almost done. Thank you for the help!

I couldn't figure out which dates you wanted to chart. So I just charted all the dates that had data (E5:M7) in your example workbook. The dates should appear on the x axis.

Sub NewGraph_A4()
 
    ActiveSheet.ChartObjects.Delete
    
    With ActiveSheet.ChartObjects.Add _
        (Left:=150, Width:=800, Top:=150, Height:=400)
        
        With .chart
            
            '.SetSourceData Source:=Range("wkly_alabaster_b", "wkly_alabaster_c")
            .SetSourceData Source:=Sheets("Sheet1").Range("E5:M7"), PlotBy:=xlRows
                        
            .ChartType = xlLine
            .Axes(xlCategory).TickLabels.Orientation = xlUpward
            .Legend.Font.Size = 13
            
            With .Axes(xlValue)
                .MajorUnit = 0.1
                .MinorUnit = 0.1
                .MaximumScale = 1
            End With
            .Axes(xlValue, xlPrimary).TickLabels.Font.Size = 15
            .Axes(xlCategory, xlPrimary).TickLabels.Font.Size = 15
            
            .SeriesCollection(1).Name = "Physical"
            .SeriesCollection(2).Name = "Economic"
            
            .HasTitle = True
            With .ChartTitle
                .Text = Worksheets("Sheet1").Range("A4").Value
                .Font.Name = "Calibri"
                .Font.FontStyle = "Regular"
            End With
            
        End With
        
    End With
     
End Sub

Thank you for the reply. There is one more thing I need to mention.
The ranges are dynamic and you can see that when you go to Name Manager and see what the named ranges are.
There is a lot going on in terms the Offset function. When you change the number in the top leftmost cell in the sheet, the number of cells in the range is selected accordingly.
I cannot simply use the correction above because it's is very important that I keep that dynamic functionality.

Here are the instructions I used- http://peltiertech.com/Excel/Charts/DynamicLast12.html

Try this...

.SetSourceData Source:=Range("wkly_alabaster_b").Offset(-1).Resize(3), PlotBy:=xlRows

Aaand it works as intended. Thank you very much for the help!

You're welcome.

This could work as well without the dynamic named ranges. The code could calculate your dynamic range.
.SetSourceData Source:=[E5].Resize(3, [A1].value), PlotBy:=xlRows

Saved me a solid 2 days of work wit that last bit..
Thanks a bunch! =)

I was about to make 3 ranges to display each chart according to the instructions I posted above. For a total of about 50 charts.
Glad to see it wasn't necessary.
I will read up on that Resize function you were using.