Grouping project names!!!

[devpp]

Hi,
I have a excel sheet with two columns.One with username and the other is projects.Each user has more than one projects.I want to make a new list (In a new sheet)with user name and all the projects the particular user is associated with.How can I do this with a help a Macro?
Thanks...

[AB33]

If a user has more than project linked with, where do the projects appear? which column/s

[arlu1201]

Try this code

Option Explicit

Sub create_sheets()
Dim i As Long, lrow As Long
Dim sname As String

Application.ScreenUpdating = False

With Worksheets("ProjectResourceReport")
    lrow = .Range("A" & .Rows.Count).End(xlUp).Row
    For i = 2 To lrow
        sname = .Range("A" & i).Value
        If Not Evaluate("ISREF('" & sname & "'!A1)") Then
            Worksheets.Add(After:=Worksheets(Worksheets.Count)).Name = sname
            Worksheets(sname).Range("A1").Value = "Projects"
        End If
        Worksheets(sname).Range("A" & Rows.Count).End(xlUp).Offset(1, 0).Value = .Range("B" & i).Value
    Next i
End With

MsgBox "Done"

Application.ScreenUpdating = True

End Sub

Copy the Excel VBA code
Select the workbook in which you want to store the Excel VBA code
Hold the Alt key, and press the F11 key, to open the Visual Basic Editor
Choose Insert | Module
Where the cursor is flashing, choose Edit | Paste

To run the Excel VBA code:
Choose View | Macros
Select a macro in the list, and click the Run button

[devpp]

Hi arlu1201,
Thanks for the reply.
How can I make all the usernames appear in the same sheet and their projects seperated by comma.
Username in one column and Projects in another column.

Thank you.

[arlu1201]

You do not want the output per user in a separate sheet?

[devpp]

No it has to be actually like this
A B
abraham_d iphone,android,common....
abramson_c iPhone 3.2,Android3.1,Tablet 1.0,iPhone 3.1.1,iPhone 3.0,iPhone 3.3,

[:) Sixthsense :)]

Use Pivot Table, refer the attached file for details.

Place the Cursor In A5 cell and do right Click>>Expand/Collapse>>Try Expand Entire Field Or Collapse Entire Field. Click the Plus Sign individually to see the individual data when the field is in collapsed mode.

Edit: Oopss I have not pressed F5 to refresh the page. Just worked with excel file based on first post

[arlu1201]

Sorry, i misunderstood that you want 1 sheet per project.

Find the updated code

Option Explicit

Sub group_projects()
Dim i As Long, lrow As Long

Application.ScreenUpdating = False

Worksheets.Add(after:=Worksheets(1)).Name = "Output"
Worksheets("ProjectResourceReport").Cells.Copy Worksheets("Output").Range("A1")

With Worksheets("Output")
    lrow = .Range("A" & .Rows.Count).End(xlUp).Row
    .Sort.SortFields.Clear
    .Sort.SortFields.Add Key:=Range("A:A") _
        , SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
    With .Sort
        .SetRange Range("A:B")
        .Header = xlYes
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
    
    For i = lrow To 2 Step -1
        If .Range("A" & i).Value = .Range("A" & i - 1).Value Then
            .Range("B" & i - 1).Value = .Range("B" & i - 1).Value & ", " & .Range("B" & i).Value
            .Rows(i).Delete
        End If
    Next i
End With

MsgBox "Done"

Application.ScreenUpdating = True

End Sub

[devpp]

Thanks a lot guys!!!

[arlu1201]

Based on your last post in this thread, its apparent that you are satisfied with the solution(s) you've received and have solved your question, but you haven't marked your thread as "SOLVED". I will do it for you this time.

In future, to mark your thread as Solved, you can do the following -
Select Thread Tools-> Mark thread as Solved.

Incase your issue is not solved, you can undo it as follows -
Select Thread Tools-> Mark thread as Unsolved.

Also, since you are relatively new to the forum, i would like to inform you that you can thank those who have helped you by clicking the small star icon located in the lower left corner of the post which helped you. This adds to the reputation of the person who has taken the time to help you.